Se l'output XML è relativamente piccolo (< 4000 caratteri), quindi è possibile utilizzare questo SP:
IF EXISTS (SELECT TOP 1 1 FROM sys.objects WHERE object_id = OBJECT_ID('dbo.USP_WRITE_UNICODE_STRING_TO_FILE') AND type = 'P')
BEGIN
DROP PROCEDURE dbo.USP_WRITE_UNICODE_STRING_TO_FILE
END
GO
-- =============================================
-- Description: Writes the specified Unicode string to the specified file.
-- Permissions: This stored procedure uses xp_cmdshell which is disabled by default. To enable it:
-- 1. In Management Studio connect to a component of SQL Server.
-- 2. In Object Explorer, right-click the server, and then click Facets.
-- 3. In the View Facets dialog box, expand the Facet list, and select the Surface Area Configuration.
-- 4. In the Facet properties area, select XPCmdShellEnabled property and set its value to True.
-- 5. Click OK.
-- Example: EXEC dbo.USP_WRITE_UNICODE_STRING_TO_FILE'<root> <a b="c" /> </root>', 'C:\Test.xml', 1;
-- =============================================
CREATE PROCEDURE dbo.USP_WRITE_UNICODE_STRING_TO_FILE
(
@Str NVARCHAR(4000),
@XmlFilePath NVARCHAR(256),
@Debug BIT = 0
)
AS
BEGIN
SET NOCOUNT ON;
DECLARE @Str1 NVARCHAR(MAX),
@Cmd NVARCHAR(4000),
@MaxLen int = 4000;
--see: http://technet.microsoft.com/en-us/library/bb490897.aspx
SET @Str1 = REPLACE(REPLACE(REPLACE(@Str, '>', '^>'), '<', '^<'), '"', '^"');
-- '>' Writes the command output to a file
SET @Str1 =N'ECHO ' + @Str1 + N'>"'+ @XmlFilePath + N'"';
IF @Debug = 1
BEGIN
DECLARE @Msg varchar(128) = 'The total lenght is ' + CAST(LEN(@Str1) AS VARCHAR(10)) + ' characters.'
PRINT @Msg;
PRINT @Str1;
END
IF (LEN(@Str1) > @MaxLen)
RAISERROR ('The input string is too long', 11, 0);
ELSE
SET @Cmd = CAST (@Str1 AS NVARCHAR(4000));
EXEC master..xp_cmdshell @Cmd, NO_OUTPUT;
END
GO
--Test 1
DECLARE @Str NVARCHAR(4000);
DECLARE @Xml xml = '<root> <a b="c" /> </root>';
SET @Str = CAST (@Xml AS NVARCHAR(4000));
EXEC dbo.USP_WRITE_UNICODE_STRING_TO_FILE @Str, 'C:\Test.xml', 1;
GO
--Test 2
DECLARE @Str NVARCHAR(4000);
SET @Str = REPLICATE('a', 4000);
EXEC dbo.USP_WRITE_UNICODE_STRING_TO_FILE @Str, 'C:\Test.xml', 1;
GO
Se non si lavora con Unicode, quindi è possibile creare un altro SP: USP_WRITE_NON_UNICODE_STRING_TO_FILE, che sarà molto simile alla precedente con le seguenti modifiche:
CREATE PROCEDURE dbo.USP_WRITE_NON_UNICODE_STRING_TO_FILE
(
@Str VARCHAR(8000),
@XmlFilePath NVARCHAR(256),
@Debug BIT = 0
)
AS
BEGIN
SET NOCOUNT ON;
DECLARE @Str1 VARCHAR(MAX),
@Cmd VARCHAR(8000),
@MaxLen int = 8000;
...
SET @Cmd = CAST (@Str1 AS VARCHAR(8000));
Tale SP consente l'utilizzo di due volte maggiore della stringa di ingresso (< 8000 caratteri).
Se il tuo XML è più lungo di 8000 ma inferiore a 1 MB puoi utilizzare sqlcmd utility senza: comando XML ON. Semplifica enormemente l'utilizzo dell'utilità perché non è necessario un file_input separato con: comando XML ON incluso. Ecco un esempio:
DECLARE @Cmd NVARCHAR(4000);
SET @Cmd = N'sqlcmd -S ' + @@SERVERNAME + N' -d ' + DB_NAME() +
N' -Q "SET NOCOUNT ON; DECLARE @Xml xml = ''<root> <a >b</a> </root>''; SELECT CONVERT(NVARCHAR(MAX), @Xml);" -o "C:\Test.xml" -y 0';
PRINT @Cmd;
EXEC master..xp_cmdshell @Cmd, NO_OUTPUT;
È possibile anche utilizzare un SP qui:
CREATE PROCEDURE dbo.USP_SAMPLE_PROCEDURE
AS
BEGIN
SET NOCOUNT ON;
DECLARE @Xml xml;
SET @Xml = (SELECT name, type_desc FROM sys.objects FOR XML PATH('object'), ROOT('sys.objects'));
SELECT CONVERT(NVARCHAR(MAX), @Xml)
END
GO
DECLARE @Cmd NVARCHAR(4000);
SET @Cmd = N'sqlcmd -S ' + @@SERVERNAME + N' -d ' + DB_NAME() +
N' -Q "EXEC dbo.USP_SAMPLE_PROCEDURE;" -o "C:\Test.xml" -y 0';
PRINT @Cmd;
EXEC master..xp_cmdshell @Cmd, NO_OUTPUT;
GO
Se il vostro XML è più di 1 MB si dovrebbe usare: XML ON comando in uno script separato e specificare come - i parametro input_file.
È necessario specificare catalogo e lo schema per la tabella anche se (cioè @Table dovrebbe essere del .dbo formato [database]. [Tabella]) – Gausie