modo pulito per dividere una serie in tre parti e visualizzare all'utente

Question

Ho un array ordinato in uno script perl per esempio:

qw(aaa bbb ccc ddd eee fff ggg hhh iii jjj kkk lll) 

C'è un modo semplice per visualizzare in tre colonne in modo che

1. primo terzo è nella colonna di sinistra
2. metà terzo è nella colonna centrale
3. e l'ultimo terzo è in colonna di destra

Questo è così gli elementi possono essere visualizzati scorrendo lungo lo schermo anziché attraverso di esso. ad esempio

aaa eee iii 
bbb fff jjj 
ccc ggg kkk 
ddd hhh lll 

ho cercato di usare il modulo ma è sempre complicato e pensato che ci potrebbe essere una soluzione elegante. In definitiva, intendo usarlo per qualcosa di simile a select in bash.

Grazie.

Answer 1

use List::MoreUtils qw(part); 
my $num_rows = int(@a/3); 
my @aoa = map [ @a[@$_] ], part { $_ % $num_rows } 0..$#a; 
print("@$_\n") for @aoa; 

o

use List::MoreUtils qw(part); 
my $num_rows = int(@a/3); 
my @aoa = part { $_ % $num_rows } 0..$#a; 
print("@a[ @$_ ]\n") for @aoa; 

o

my $num_rows = int(@a/3); 
for my $row_num (0..$num_rows-1) { 
    print("@a[ map { $row_num + $num_rows*$_ } 0..2 ]\n"); 
} 

---

versioni di cui sopra che non assume @a% 3 == 0.

use List::MoreUtils qw(part); 
use POSIX   qw(ceil); 
my $num_rows = ceil(@a/3); 
my @aoa = map [ @a[@$_] ], part { $_ % $num_rows } 0..$#a; 
print("@$_\n") for @aoa; 

o

use List::MoreUtils qw(part); 
use POSIX   qw(ceil); 
my $num_rows = ceil(@a/3); 
my @aoa = part { $_ % $num_rows } 0..$#a; 
print("@a[ @$_ ]\n") for @aoa; 

o

use POSIX qw(ceil); 
my $num_rows = ceil(@a/3); 
for my $row_num (0..$num_rows-1) { 
    print("@a[ grep { $_ < @a } map { $row_num + $num_rows*$_ } 0..2 ]\n"); 
} 

Answer 2

Ecco la mia soluzione, spero che ti aiuti.

use strict; 
use warnings; 

my @arr = ("aaa", "bbb", "ccc", "ddd", "eee", "fff", "ggg", "hhh", "iii", "jjj", "kkk", "lll"); 
my $size = @arr; 

my $column = 3; 

my $mod = $size/$column; 

my $i = $size; 
my $count = 0; 
while ($i > 0) { 
    my $k = $count; 
    while ($k < $size) { 
     print "$arr[$k]\t"; 
     $k += $mod; 
    } 
    print "\n"; 
    $count++; 
    $i -= $column; 
} 

Answer 3

my @foo = qw(aaa bbb ccc ddd eee fff ggg hhh iii jjj kkk lll); 
my $rows = int((@foo+2)/3); 
my @row; 
$row[$_ % $rows][$_/$rows] = $foo[$_] for 0..$#foo; 
for my $row (@row) { 
    print join(' ', @$row), "\n"; 
} 

Answer 4

Un'altra opzione:

use strict; 
use warnings; 

my @a = qw(aaa bbb ccc ddd eee fff ggg hhh iii jjj kkk lll); 
my @aoa; 
push @{ $aoa[ $_ % 4 ] }, $a[$_] for 0 .. $#a; 
print "@{ $_ }\n" for @aoa; 

Answer 5

Dopo aver letto questa domanda, sembrava un po 'come un example che ho letto nel documenti per Perl6::Form. (Che è l'implementazione Perl5)

use strict; 
use warnings; 
use Perl6::Form; 

my @array = qw'aaa bbb ccc ddd eee fff ggg hhh iii jjj kkk lll'; 

print form 
    "{[[[[[:} {:[[[[:} {:[[[[[}", 
    \@array, \@array, \@array; 

aaa  eee  iii 
bbb  fff  jjj 
ccc  ggg  kkk 
ddd  hhh  lll 

Non funzionerà come si vuole che, se una delle stringhe è più lungo di quanto sia stato assegnato per esso.

... 
$array[-1] .= ' lllllll'; 
... 

aaa  fff  kkk 
bbb  ggg  lll 
ccc  hhh  lllllll 
ddd  iii 
eee  jjj 

Naturalmente si potrebbe calcolare la larghezza desiderata prima della chiamata a form.

... 

use List::Util qw'max'; 

my $max_length = max 5, map length, @array; # at least 5 
my $TERMINAL_WIDTH = 80; 
my $number_of_cols = int($TERMINAL_WIDTH/($max_length+1)); 

my $single = '{:' . ('[' x ($max_length-4)) . ':} '; 

print $single, "\n\n"; # debug statement 

print form 
    $single x $number_of_cols, 
    (\@array) x $number_of_cols; 

{:[[[[[[[:} 

aaa   ccc   eee   ggg   iii   kkk 
bbb   ddd   fff   hhh   jjj   lll lllllll 
                      80^

Answer 6

4 LOC: molto semplice ... GODETEVI

my @tokens = qw(aaa bbb ccc ddd eee fff ggg hhh iii jjj kkk lll); 
my $text = join(" ",@tokens); 
while($text =~ /[^ ]+ [^ ]+ [^ ]+/g) 
{ 
    print "$&\n"; 
} 

Samir