Ecco una trasformazione più generico che ottiene un qualsiasi numero di parametri di stringa di query da un dato URL:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:param name="pUrl" select=
"'http:www.somedomain.com/index.aspx?myVar=test&myVar2=anotherTest&myVar3=yetAnotherTest'"/>
<xsl:template match="/">
<xsl:call-template name="GetQueryStringParams"/>
</xsl:template>
<xsl:template name="GetQueryStringParams">
<xsl:param name="pUrl" select="$pUrl"/>
<xsl:variable name="vQueryPart" select=
"substring-before(substring-after(concat($pUrl,'?'),
'?'),
'?')"/>
<xsl:variable name="vHeadVar" select=
"substring-before(concat($vQueryPart,'&'), '&')"/>
<xsl:element name="{substring-before($vHeadVar, '=')}">
<xsl:value-of select="substring-after($vHeadVar, '=')"/>
</xsl:element>
<xsl:variable name="vRest" select="substring-after($vQueryPart, '&')"/>
<xsl:if test="string-length($vRest) > 0">
<xsl:call-template name="GetQueryStringParams">
<xsl:with-param name="pUrl" select=
"concat('?', substring(substring-after($vQueryPart, $vHeadVar), 2))"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
quando questa trasformazione viene applicata su qualsiasi documento XML (non utilizzato), il risultato voluto e corretto viene prodotto:
<myVar>test</myVar>
<myVar2>anotherTest</myVar2>
<myVar3>yetAnotherTest</myVar3>
fonte
2012-02-09 13:50:14
Quindi dovrei dividere l'URL per accedere ai valori di myVar e myVar2? –
@ user1001421, ho aggiornato la mia risposta. –
Fantastico. Grazie mille per il vostro aiuto. Proprio quello che stavo cercando. –