Passaggio di una variabile URL in xsl

Question

È possibile passare una variabile URL in xsl.

EG. http: www.somedomain.com/index.aspx myVar = test & MyVar2 = anotherTest

mi piacerebbe essere in grado di utilizzare i valori di myVar e MyVar2 nella logica del mio file XSL?. Grazie.

Answer 1

Certo, è possibile. Utilizza l'elemento xsl:param nell'elemento xsl:stylesheet e passa il parametro dal tuo motore XSL.

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:param name="url"/> 

Quindi utilizzare stringhe funzioni, ad esempio:

<xsl:variable name="right-part" select="substring-after($url, 'myVar=')"/> 
<xsl:value-of select="substring-before(substring-before($right-part, 'myVar2='), '&amp;')"/> 
<xsl:text>|</xsl:text> 
<xsl:value-of select="substring-after($right-part, 'myVar2=')"/> 

Answer 2

Ecco una trasformazione più generico che ottiene un qualsiasi numero di parametri di stringa di query da un dato URL:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:param name="pUrl" select= 
"'http:www.somedomain.com/index.aspx?myVar=test&amp;myVar2=anotherTest&amp;myVar3=yetAnotherTest'"/> 

<xsl:template match="/"> 
    <xsl:call-template name="GetQueryStringParams"/> 
</xsl:template> 

<xsl:template name="GetQueryStringParams"> 
    <xsl:param name="pUrl" select="$pUrl"/> 

     <xsl:variable name="vQueryPart" select= 
     "substring-before(substring-after(concat($pUrl,'?'), 
             '?'), 
         '?')"/> 

     <xsl:variable name="vHeadVar" select= 
     "substring-before(concat($vQueryPart,'&amp;'), '&amp;')"/> 

     <xsl:element name="{substring-before($vHeadVar, '=')}"> 
     <xsl:value-of select="substring-after($vHeadVar, '=')"/> 
     </xsl:element> 

    <xsl:variable name="vRest" select="substring-after($vQueryPart, '&amp;')"/> 

    <xsl:if test="string-length($vRest) > 0"> 
     <xsl:call-template name="GetQueryStringParams"> 
     <xsl:with-param name="pUrl" select= 
     "concat('?', substring(substring-after($vQueryPart, $vHeadVar), 2))"/> 
     </xsl:call-template> 
    </xsl:if> 
</xsl:template> 
</xsl:stylesheet> 

quando questa trasformazione viene applicata su qualsiasi documento XML (non utilizzato), il risultato voluto e corretto viene prodotto:

<myVar>test</myVar> 
<myVar2>anotherTest</myVar2> 
<myVar3>yetAnotherTest</myVar3>