Come imitare copy-namespaces = "no" in XSLT 1.0?

Question

Desidero riscrivere questo pezzo xslt in XSLT 1.0, che non supporta "copy-namespaces".

<xsl:copy-of copy-namespaces="no" select="maml:alertSet/maml:alert" /> 

Come?

Answer 1

I seguenti imita l'XSLT 2.0 costrutto:

Creare modelli in una modalità che si ri-costruire i nodi senza spazi dei nomi:

<!-- generate a new element in the same namespace as the matched element, 
    copying its attributes, but without copying its unused namespace nodes, 
    then continue processing content in the "copy-no-namepaces" mode --> 

<xsl:template match="*" mode="copy-no-namespaces"> 
    <xsl:element name="{local-name()}" namespace="{namespace-uri()}"> 
     <xsl:copy-of select="@*"/> 
     <xsl:apply-templates select="node()" mode="copy-no-namespaces"/> 
    </xsl:element> 
</xsl:template> 

<xsl:template match="comment()| processing-instruction()" mode="copy-no-namespaces"> 
    <xsl:copy/> 
</xsl:template> 

apply-templates per l'elemento desiderato (s) in quanto modalità:

<xsl:apply-templates select="maml:alertSet/maml:alert" mode="copy-no-namespaces"/>