Come controllare il rendering booleano in XSLT

Question

Per conformarsi alla <boolean>spec of Xml-RPC ho bisogno di trasformare il mio xs:boolean da true|false a 1|0.

Ho risolto questo utilizzando xsl: choose

<xsl:template match="Foo"> 
    <member> 
     <name>Baz</name> 
     <value> 
      <boolean> 
       <xsl:choose> 
        <xsl:when test=".='true'">1</xsl:when> 
        <xsl:otherwise>0</xsl:otherwise> 
       </xsl:choose> 
      </boolean> 
     </value> 
    </member> 
</xsl:template> 

ma chiedevo se c'è un modo meno fragile di controllare come i valori booleani sono resi quando trasformata con XSLT 1.0.

Answer 1

Uso:

number(boolean(.)) 

Per la definizione della funzione XPath norma number() produce esattamente {0, 1} quando applicati, rispettivamente, sulla {true(), false()}

Attenzione! Se si utilizza questa costruzione su stringhe, il risultato sarà valido per entrambi 'false' e 'true', perché, per i parametri di stringa, boolean() is true if and only if its length is non-zero.

Quindi, se si desidera convertire stringhe, non booleani, quindi usare questa espressione:

number(not(. = 'false')) 

Qui di seguito è una verifica XSLT basata:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="text()"> 
    <xsl:value-of select="number(not(. = 'false'))"/> 
</xsl:template> 
</xsl:stylesheet> 

quando questa trasformazione viene applicata al seguente documento XML:

<t> 
<x>true</x> 
<y>false</y> 
</t> 

il voluto, risultato corretto è prodotta:

<t> 
    <x>1</x> 
    <y>0</y> 
</t>