Controllo del nome file valido. Qual è il modo migliore?

Question

Vedere l'oggetto di presentazione per la domanda.

1) Mi ricordo di aver visto una scelta davvero cool in VB.NET utilizzando LINQ per abbinare con "LIKE%'

2) So che le espressioni regolari lavoreranno e ho il sospetto che si tradurrà nel codice più breve e, probabilmente, non sarà troppo difficile da leggere per un semplice test come

Ecco quello che ho fatto Attenzione:... stai andando odi

Private Shared Function FileNameIsOk(ByVal fileName As String) As Boolean 

    For Position As Integer = 0 To fileName.Length - 1 

     Dim Character As String = fileName.Substring(Position, 1).ToUpper 
     Dim AsciiCharacter As Integer = Asc(Character) 

     Select Case True 

      Case Character = "_" 'allow _ 
      Case Character = "." 'allow . 
      Case AsciiCharacter >= Asc("A") And AsciiCharacter <= Asc("A") 'Allow alphas 
      Case AsciiCharacter >= Asc("0") AndAlso AsciiCharacter <= Asc("9") 'allow digits 

      Case Else 'otherwise, invalid character 
       Return False 

     End Select 

    Next 

    Return True 

End Function 

Answer 1

Vecchio ora, ma ho visto questo e solo dovuto aggiungere una nuova risposta. Le attuali risposte accettate e altre sono solo più complicate del necessario. In effetti, può essere ridotto a una sola riga:

Public Shared Function FilenameIsOK(ByVal fileName as String) as Boolean 
    Return Not (Path.GetFileName(fileName).Intersect(Path.GetInvalidFileNameChars()).Any() OrElse Path.GetDirectoryName(fileName).Intersect(Path.GetInvalidPathChars()).Any()) 
End Function 

Anche se io non lo consiglio a scrivere in questo modo. Break it up solo un po 'per migliorare la leggibilità:

Public Shared Function FilenameIsOK(ByVal fileName as String) as Boolean 
    Dim file As String = Path.GetFileName(fileName) 
    Dim directory As String = Path.GetDirectoryName(fileName) 

    Return Not (file.Intersect(Path.GetInvalidFileNameChars()).Any() _ 
       OrElse _ 
       directory.Intersect(Path.GetInvalidPathChars()).Any()) 
End Function 

Un altro punto qui, è che spesso il modo migliore per affrontare i problemi del file system è quello di lasciare che il file system vi dico: basta provare a aprire o creare il file in questione e gestire l'eccezione. Funziona particolarmente bene, perché probabilmente dovrai farlo comunque. Qualsiasi cosa tu faccia qui è uno sforzo duplicato per il lavoro che dovrai ancora inserire in un gestore di eccezioni.

Answer 2

Francamente, mi basta usare l'oggetto FileInfo built in. NET e controlla l'eccezione per l'invalidità. Vedere this riferimenti per i dettagli.

Answer 3

Si tratta di una regex e C#, ma:

using System; 
using System.Text.RegularExpressions; 

/// <summary> 
/// Gets whether the specified path is a valid absolute file path. 
/// </summary> 
/// <param name="path">Any path. OK if null or empty.</param> 
static public bool IsValidPath(string path) 
{ 
    Regex r = new Regex(@"^(([a-zA-Z]\:)|(\\))(\\{1}|((\\{1})[^\\]([^/:*?<>""|]*))+)$"); 
    return r.IsMatch(path); 
} 

Answer 4

Come su Path.GetInvalidFileNameChars e Path.GetInvalidPathChars?

Public Shared Function FilenameIsOK(ByVal fileNameAndPath as String) as Boolean 
    Dim fileName = Path.GetFileName(fileNameAndPath) 
    Dim directory = Path.GetDirectoryName(fileNameAndPath) 
    For each c in Path.GetInvalidFileNameChars() 
     If fileName.Contains(c) Then 
      Return False 
     End If 
    Next 
    For each c in Path.GetInvalidPathChars() 
     If directory.Contains(c) Then 
      Return False 
     End If 
    Next 
    Return True 
End Function 

Answer 5

Anche se questo è abbastanza vecchio, è ancora valido, e sono finito qui cercando la soluzione a come controllare il nome del file per i caratteri non validi. Ho guardato la risposta accettata e ho trovato alcuni buchi.

Speriamo che queste modifiche siano di qualche utilità per qualcun altro.

Public Function FilenameIsOK(ByVal fileNameAndPath As String) As Boolean 
    Dim fileName As String = String.Empty 
    Dim theDirectory As String = fileNameAndPath 

    Dim p As Char = Path.DirectorySeparatorChar 

    Dim splitPath() As String 
    splitPath = fileNameAndPath.Split(p) 
    If splitPath.Length > 1 Then 
     fileName = splitPath(splitPath.Length - 1) 
     theDirectory = String.Join(p, splitPath, 0, splitPath.Length - 1) 
    End If 

    For Each c As Char In Path.GetInvalidFileNameChars() 
     If fileName.Contains(c) Then 
      Return False 
     End If 
    Next 

    For Each c As Char In Path.GetInvalidPathChars() 
     If theDirectory.Contains(c) Then 
      Return False 
     End If 
    Next 
    Return True 
End Function 

Answer 6

provare questo

Public Function IsValidFileName(ByVal fn As String) As Boolean 
    Try 
     Dim fi As New IO.FileInfo(fn) 
    Catch ex As Exception 
     Return False 
    End Try 
    Return True 
End Function 

Answer 7

Ok. Buone idee. Ma l'iterazione manuale dei caratteri "non validi" non è il modo migliore, quando si lavora con migliaia di file.

Public BadChars() As Char = IO.Path.GetInvalidFileNameChars 

For m = 0 To thousands_of_files - 1 
    '.. 
    if currFile.Name.ToCharArray.Intersect(BadChars).Count > 1 Then 
     ' the Name is invalid - what u gonna do? =) 
    end if 
    '.. 
    '.. 
Next 

Answer 8

Prova questa

Funzione IsValidFileNameOrPath (nome ByVal come stringa) come booleano

Dim i come numero intero Dim dn, fn come stringa

i = InStrRev(name, "\") : dn = Mid(name, 1, i) : fn = Mid(name, i + 1) 
    MsgBox("directory = " & dn & " : file = " & fn) 

    If name Is Nothing Or Trim(fn) = "" Then 
     MsgBox("null filename" & fn) 
     Return False 
    Else 
     For Each badchar As Char In Path.GetInvalidFileNameChars 
      If InStr(fn, badchar) > 0 Then 
       MsgBox("invalid filename" & fn) 
       Return False 
      End If 
     Next 
    End If 

    If dn <> "" Then 
     If InStr(dn, "\\") > 0 Then 
      MsgBox("duplicate \ = " & dn) 
      Return False 
     End If 
     For Each badChar As Char In Path.GetInvalidPathChars 
      If InStr(dn, badChar) > 0 Then 
       MsgBox("invalid directory= " & dn) 
       Return False 
      End If 
     Next 
     If Not System.IO.Directory.Exists(dn) Then 
      Try 
       Directory.CreateDirectory(dn) 
       'Directory.Delete(dn) 
      Catch 
       MsgBox("invalid path = " & dn) 
       Return False 
      End Try 
     End If 
    End If 
    Return True 
End Function 

Answer 9

Sulla base di Joel Coehoorns soluzione ben scritto, Ho aggiunto alcune funzionalità aggiuntive per la convalida.

''' <summary> 
    ''' Check if fileName is OK 
    ''' </summary> 
    ''' <param name="fileName">FileName</param> 
    ''' <param name="allowPathDefinition">(optional) set true to allow path definitions. If set to false only filenames are allowed</param> 
    ''' <param name="firstCharIndex">(optional) return the index of first invalid character</param> 
    ''' <returns>true if filename is valid</returns> 
    ''' <remarks> 
    ''' based on Joel Coehoorn answer in 
    ''' http://stackoverflow.com/questions/1014242/valid-filename-check-what-is-the-best-way 
    ''' </remarks> 
    Public Shared Function FilenameIsOK(ByVal fileName As String, _ 
             Optional ByVal allowPathDefinition As Boolean = False, _ 
             Optional ByRef firstCharIndex As Integer = Nothing) As Boolean 

     Dim file As String = String.Empty 
     Dim directory As String = String.Empty 

     If allowPathDefinition Then 
      file = Path.GetFileName(fileName) 
      directory = Path.GetDirectoryName(fileName) 
     Else 
      file = fileName 
     End If 

     If Not IsNothing(firstCharIndex) Then 
      Dim f As IEnumerable(Of Char) 
      f = file.Intersect(Path.GetInvalidFileNameChars()) 
      If f.Any Then 
       firstCharIndex = Len(directory) + file.IndexOf(f.First) 
       Return False 
      End If 

      f = directory.Intersect(Path.GetInvalidPathChars()) 
      If f.Any Then 
       firstCharIndex = directory.IndexOf(f.First) 
       Return False 
      Else 
       Return True 
      End If 
     Else 
      Return Not (file.Intersect(Path.GetInvalidFileNameChars()).Any() _ 
         OrElse _ 
         directory.Intersect(Path.GetInvalidPathChars()).Any()) 
     End If 

    End Function 

Answer 10

Non posso prendermi il merito di questo (ben due) transatlantico. L'ho trovato mentre cercavo su google, non ricordo dove l'ho trovato.

Dim newFileName As String = "*Not<A>Good:Name|For/\File?" 
    newFileName = String.Join("-", fileName.Split(IO.Path.GetInvalidFileNameChars)) 

Answer 11

Public Function IsValidFileName(nFile As String) As Boolean 
    Try 
     Dim S As String = Path.GetFileName(nFile) 
    Catch 
     Return False 
    End Try 
    Return True 
End Function