Come usare Kotlin nei progetti AppEngine usando Gradle

Question

Come dice il titolo, come posso usare Kotlin nello sviluppo di progetti AppEngine? Sto usando IntelliJ/Android Studio con Gradle come strumento di creazione.

Answer 1

Poiché AppEngine esegue file .class compilati, non gli interessa il linguaggio JVM. Questo significa che possiamo usare Kotlin.

Un modo per farlo è utilizzando Gradle e lo Gradle App Engine plugin. Creare un progetto con un build.gradle simile a this. Quindi aggiungi le dipendenze di Kotlin e applica il plugin. Il file build finale simile a questa:

buildscript { 
    ext.kotlin_version = '1.0.6' //replace with latest Kotlin version 
    repositories { 
     mavenCentral() 
    } 
    dependencies { 
     classpath 'com.google.appengine:gradle-appengine-plugin:1.9.32' //Replace with latest GAE plugin version 
     classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version" 
    } 
} 

repositories { 
    mavenCentral(); 
} 

apply plugin: 'java' 
apply plugin: 'kotlin' 
apply plugin: 'war' 
apply plugin: 'appengine' 

sourceCompatibility = JavaVersion.VERSION_1_7 
targetCompatibility = JavaVersion.VERSION_1_7 

dependencies { 
    appengineSdk 'com.google.appengine:appengine-java-sdk:1.9.32' //Replace with latest GAE SDK version 
    compile 'javax.servlet:servlet-api:2.5' 
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version" 
} 

appengine { 
    downloadSdk = true 
    appcfg { 
     oauth2 = true 
    } 
} 

Dal M11 non è necessario avere una directory separata per i file Kotlin quindi si può solo aggiungere i tuoi file .kt a src/main/java.