excel vba: Tipi speciali - Funzioni come argomenti delle funzioni

Question

Non esiste un tipo speciale per le funzioni in VBA. È difficile per me vedere come aggiungere funzioni come argomenti alle funzioni in VBA di Excel.

Quello che sto cercando di realizzare è qualcosa di simile:

function f(g as function, x as string) as string 
     f = g(x) 
end function 

Attualmente, ho un gruppo di piccoli tutte le funzioni di ripetere se stessi, ma con una sola chiamata a una funzione specifica.

Answer 1

Dal codice, la funzione g accetta un parametro stringa e restituisce una stringa. Vi suggerisco di creare un modulo di classe chiamato IStringFunction ad agire come la definizione di un'interfaccia che tutte le funzioni sosterrà, in tal modo:

modulo di classe: IStringFunction

Public Function Evaluate(ByVal s As String) As String 
End Function 

Poi, crea un paio di esempi di funzioni implementa questa interfaccia: Modulo

Classe: HelloStringFunction

Implements IStringFunction 

Public Function IStringFunction_Evaluate(ByVal s As String) As String 
    IStringFunction_Evaluate = "hello " & s 
End Function 

modulo di classe: GoodbyeStringFunction

Implements IStringFunction 

Public Function IStringFunction_Evaluate(ByVal s As String) As String 
    IStringFunction_Evaluate = "goodbye " & s 
End Function 

... e, infine, un po 'di codice di prova per esercitare le funzioni di:

(Standard) Modulo: test

Sub Test() 

    Dim oHello As New HelloStringFunction 
    Dim oGoodbye As New GoodbyeStringFunction 

    MsgBox Evaluate(oHello, "gary") 
    MsgBox Evaluate(oGoodbye, "gary") 

End Sub 

Private Function Evaluate(ByVal f As IStringFunction, ByVal arg As String) As String 
    Evaluate = f.Evaluate(arg) 
End Function 

Nota che la classe che implementa l'interfaccia deve avere metodi denominati <Interface>_<Method> come nell'esempio sopra, non solo <Method> come ti aspetteresti.

Scaricare il simple demo o intermediate demo qui

Answer 2

Dal VBA ha le sue radici in un linguaggio interattivo, ha sempre avuto la capacità di eseguire il testo:

function f(g as string, x as string) as string 
     f = application.run(g,x) 
end function 

MyStringA = f("functionA",string1) 
MyStringB = f("functionB",string1) 

Answer 3

E 'possibile passare una funzione come un argomento, e ottenere esattamente il comportamento che stai cercando, ma è un po 'hacky. Questo risultato è ottenuto sfruttando la proprietà predefinita di una classe,

creare una classe myFunction contenente la funzione

Public Function sayHi(ByVal s As String) As String 
    sayHi = "Hi " & s 
End Function 

Export, e aprire il.file di cls in un editor di testo

Dovreste vedere da qualche parte nel file, una linea che definisce la funzione

Public Function sayHi(ByVal s As String) As String 

Sotto di esso, aggiungere la riga Attribute Value.VB_UserMemId = 0, in modo che ora assomiglia a questo:

Public Function sayHi(ByVal s As String) As String 
Attribute Value.VB_UserMemId = 0 
    sayHi = "Hi " & s 
End Function 

Quello che hai fatto è quello di segnare sayHi come default property della classe. Ora è possibile chiamare la funzione di solo l'oggetto di classe class(args), piuttosto che class.function(args)

Salvare il file modificato e importarlo nel progetto VBA

modulo di test

Sub test() 
    Dim parameterFunction As Object   'this is what we'll be passing to our routine 
    Set parameterFunction = New myFunction 'create instance of the function object 
    MsgBox f(parameterFunction, "Greedo") 
End Sub 

Function f(ByVal g As Object, ByVal x As String) As String 
     f = g(x) 
End Function 

* NB, questo modo in cui puoi passare qualsiasi funzione; ma puoi invece specificare ByVal g As IStringFunction per ottenere solo il sottoinsieme con l'interfaccia corretta come da Gary McGill's answer