in F #, come si uniscono due istanze Collections.Map?

Question

Sto cercando di unire due mappe, ma non esiste un metodo integrato per unire le raccolte. Quindi come lo fai?

Answer 1

Definire la seguente funzione:

let join (p:Map<'a,'b>) (q:Map<'a,'b>) = 
    Map(Seq.concat [ (Map.toSeq p) ; (Map.toSeq q) ]) 

esempio:

let a = Map([1,11;2,21;3,31;]) 

let b = Map([3,32; 4,41;5,51;6,61;]) 

let c = join a b 

e il risultato:

val c : Map<int,int> = 
    map [(1, 11); (2, 21); (3, 32); (4, 41); (5, 51); (6, 61)] 

Answer 2

È possibile implementare questo utilizzando Map.fold e Map.add, dato aggiuntivo è in realtà aggiungere/sostituire:

let map1 = Map.ofList [ 1, "one"; 2, "two"; 3, "three" ] 
let map2 = Map.ofList [ 2, "two"; 3, "oranges"; 4, "four" ] 


let newMap = Map.fold (fun acc key value -> Map.add key value acc) map1 map2 

printfn "%A" newMap 

Probabilmente il motivo di unione non è prevista fuori dalla scatola è che è necessario affrontare con conflitti chiave. In questo semplice algoritmo di fusione, prendiamo semplicemente la coppia di valori chiave dalla seconda mappa, questo potrebbe non essere il comportamento che vuoi.

Answer 3

Un modo alternativo è questo:

let merge (a : Map<'a, 'b>) (b : Map<'a, 'b>) (f : 'a -> 'b * 'b -> 'b) = 
    Map.fold (fun s k v -> 
     match Map.tryFind k s with 
     | Some v' -> Map.add k (f k (v, v')) s 
     | None -> Map.add k v s) a b 

Consente di decidere il valore desiderato se sono presenti chiavi duplicate.

Esempio:

let a = Map([1,11;2,21;3,31;]) 

let b = Map([3,32; 4,41;5,51;6,61;]) 

merge a b (fun k (v, v') -> v + v');; 

//Result 
val it : Map<int,int> = 
    map [(1, 11); (2, 21); (3, 63); (4, 41); (5, 51); (6, 61)] 

Si noti che la chiave 3 è diverso.