Come impongo che il campo di una struttura sia di qualche tipo?

Question

Come si impone il tipo di campi in questa struttura?

#lang racket 
(struct Car (model year)) 

Ho provato con un contratto (ma visto che sono nuovo al racket, questo non funziona, ovviamente ...: P)

(provide (contract-out 
     [Car (string? integer? . -> . Car?)])) 

esempio: Questo succeds ma non dovrebbe ...

(define my-car (Car 2008 "A3"))

Purtroppo, non sembra essere scritto da nessuna parte come per ottenere questo fatto.

Answer 1

penso che si sta colpendo almeno uno, e forse entrambe le seguenti:

1. Utilizzando (provide (contract-out ....)) significa il contratto si applica solo al confine del modulo - solo per altri moduli che require questo uno. Quindi, se il tuo esempio di test era nello stesso modulo, il contratto non si applicava. Invece è possibile utilizzare define/contract per applicare un contratto alla cosa stessa, sia nel modulo in cui è definito sia all'esterno se si è provide esso.

2. C'è un special form of contracts for structs, in cui si specifica un contratto per ogni campo. Quello che hai provato sopra è un contratto solo sulla funzione del costruttore. Anche se lo potrebbe essere essere quello che vuoi, prendere in considerazione l'utilizzo del contratto per il struct invece.

Combinando entrambi si potrebbe fare:

;; Define the contract on the struct itself. 
;; Contract is used even within this module. 
(provide car) 
(define-struct/contract car ([model string?] 
          [year integer?])) 

Se si voleva il contratto di applicare solo al confine del modulo, allora si può usare:

;; Define the contract only as `provide`d. 
;; Contract is used only for code `require`-ing this module. 
(provide (contract-out (struct car ([model string?] 
            [year integer?])))) 
(struct car (model year)) 

P.S. FWIW in Racket lo stile comune è non per scrivere in maiuscolo il nome di una struttura - car non Car.

---

Aggiornamento: Giusto per illustrare la differenza più chiaramente:

#lang racket 

(module mod racket 
    (provide car0) 
    (define-struct/contract car0 ([model string?] 
           [year integer?])) 

    (car0 "foo" "bar") ;; gives contract violation 
        ;; because contract on struct itself 

    (struct car1 (model year)) 
    (provide (contract-out (struct car1 ([model string?] 
             [year integer?])))) 

    (car1 "foo" "bar") ;; does NOT give contract violation 
        ;; because contract only on the `provide` 
) 

(require 'mod) 
(car0 "foo" "bar") ;; gives contract violation 
(car1 "foo" "bar") ;; gives contract violation