TProc <TObject> a TNotifyEvent

Question

Oltre a questo post cui risposta accettata rimane molto criptico:

@Button1.OnClick := pPointer(Cardinal(pPointer(procedure (sender: tObject) begin ((sender as TButton).Owner as TForm).Caption := 'Freedom to anonymous methods!' end)^) + $0C)^; 

mi chiedo che scendessimo sia possibile escogitare un modo più semplice e elegante, simile a:

Button.OnClick := 
        AnonProc2NotifyEvent (
        procedure (Sender: TObject) 
        begin 
         ((Sender as TButton).Owner as TForm).Caption := 'Freedom to anonymous methods!' 
        end 
        ); 

in modo da per raggiungere lo stesso scopo e dove AnonProc2NotifyEvent è un metodo del proprietario di Button con la seguente firma:

TOwnerOfButton = class(TForm) 
    Button: TButton; 
    ... 
private 
    ... 
protected 
    function AnonProc2NotifyEvent(aProc: TProc<TObject>): TNotifyEvent; 
public 
    ... 
end; 

È fattibile e, in caso affermativo, come implementarlo?

Answer 1

questo farà il lavoro abbastanza facilmente:

type 
    TNotifyEventWrapper = class(TComponent) 
    private 
    FProc: TProc<TObject>; 
    public 
    constructor Create(Owner: TComponent; Proc: TProc<TObject>); 
    published 
    procedure Event(Sender: TObject); 
    end; 

constructor TNotifyEventWrapper.Create(Owner: TComponent; Proc: TProc<TObject>); 
begin 
    inherited Create(Owner); 
    FProc := Proc; 
end; 

procedure TNotifyEventWrapper.Event(Sender: TObject); 
begin 
    FProc(Sender); 
end; 

function AnonProc2NotifyEvent(Owner: TComponent; Proc: TProc<TObject>): TNotifyEvent; 
begin 
    Result := TNotifyEventWrapper.Create(Owner, Proc).Event; 
end; 

Il parametro Owner in AnonProc2NotifyEvent è così che la durata dell'oggetto involucro può essere gestito. Senza qualcosa del genere si perderebbero istanze di TNotifyEventWrapper.

Passa come Owner, il componente a cui stai collegando l'evento. Per esempio:

Button1.OnClick := AnonProc2NotifyEvent(
    Button1, 
    procedure(Sender: TObject) 
    begin 
    (Sender as TButton).Caption := 'Clicked'; 
    end 
); 

Così, quando il tasto viene distrutto, la TNotifyEventWrapper sarà anche distrutti. L'oggetto wrapper deve vivere almeno fino a quando l'oggetto ai cui eventi è associato. E quindi la scelta di Button1 come proprietario è naturale e ovvia.

Answer 2

Per riferimento questo che voglio arrivare, ho studiato Barry Kelly 's blog post riferimento nel post prima del SO di cui sopra e si avvicinò con questa soluzione:

function TMainForm.Proc2NotifyEvent(const aProc: TNotifyReference): TNotifyEvent; 
type 
    TVtable = array[0..3] of Pointer; 
    PVtable = ^TVtable; 
    PPVtable = ^PVtable; 
begin 
    TMethod(Result).Code := PPVtable((@aProc)^)^^[3]; 
    TMethod(Result).Data := Pointer((@aProc)^); 
end; 

Ancora criptico ma incapsulato, in modo da facilitare il compito del codificatore rispetto al metodo iniziale.

Ho cercato di riordinare MethRefToMethPtr e MakeNotify e mettere tutto in un metodo.

Si noti che non v'è stato (un leggero) variazione firma del metodo, l'argomento aproc divenne const.