Che cosa significano tutti i campi per db.part/db?

Question

Sono un principiante di Datomic e sto ancora cercando di capire come è stato costruito il sistema. In particolare, non capisco quale ruolo: db.part/db riproduce come sembra essere necessario ogni volta che viene installato uno schema. Qualcuno potrebbe far luce su cosa significa tutto questo?

 
(require '[datomic.api :as d]) 
(def uri "datomic:mem://sample") 
(d/create-database uri) 
(def conn (d/connect uri)) 

(pprint (seq (d/entity dbval :db.part/db))) 

;; => 
;; ([:db/doc "Name of the system partition. The system partition includes the core of datomic, as well as user schemas: type definitions, attribute definitions, partition definitions, and data function definitions."] 
;; [:db.install/function #{:db.fn/cas :db.fn/retractEntity}] 
;; [:db.install/attribute 
;; #{:db/noHistory :db.install/partition :db/cardinality 
;;  :db.install/attribute :db/index :db/unique :db/fulltext 
;;  :db/txInstant :db/lang :db/doc :db.install/valueType :db/code 
;;  :db/isComponent :db/fn :db.install/function :db/valueType :db/ident 
;;  :fressian/tag}] 
;; [:db.install/valueType 
;; #{:db.type/uuid :db.type/bigint :db.type/uri :db.type/ref 
;;  :db.type/keyword :db.type/bytes :db.type/string :db.type/instant 
;;  :db.type/fn :db.type/long :db.type/bigdec :db.type/boolean 
;;  :db.type/double :db.type/float}] 
;; [:db.install/partition #{:db.part/db}] 
;; [:db/ident :db.part/db]) 

Answer 1

:db.part/db è la partizione per le entità dello schema (vedi la documentazione dello schema in partitions). Questi attributi db.install vengono utilizzati per attivare i hook sull'installazione di determinate entità. Che si affermano di :db.part/db non ha alcun significato speciale (afaik), questa è solo la convenzione la squadra Datomic ha scelto per rappresentare l'installazione di attributi, ecc

Così, ad esempio, quando si invia una transazione come:

[{:db/ident :person/name 
    :db/cardinality :db.cardinality/one 
    :db/valueType :db.type/string 
    :db.install/_attribute :db.part/db 
    :db/id #db/id[:db.part/db]}] 

che equivale a (in Clojure ora invece di EDN): le comunicazioni

(let [id (datomic.api/tempid :db.part/db)] 
    [[:db/add id :db/ident :person/name] 
    [:db/add id :db/cardinality :db.cardinality/one] 
    [:db/add id :db/valueType :db.type/string] 
    [:db/add :db.part/db :db.install/attribute id]]) 

allora Datomic aver aggiunto un valore per :db.part/db s' :db.install/attribute, convalidando che hai fornito il attributi richiesti per un attributo e installazione del nuovo attributo nel database in modo da poterlo utilizzare dopo la transazione.

Analogamente, è possibile utilizzare :db.install/_partition :db.part/db per installare nuove partizioni. Vedere i documenti su Installing an attribute definition e Creating new partitions.

:db.install/valueType potrebbe un giorno essere utilizzato per installare i propri tipi di valori personalizzati, ma questa funzione non è ancora pronta. :db.install/function sembra essere per uso interno. Non sono sicuro del suo scopo. Il modo documentato per install database functions è diverso.

Questi attributi (ad eccezione di :db.install/function) sono anche convenienti per le query e l'ispezione del db. Ad esempio, siamo in grado di tirare fuori l'insieme di tutti i tipi di valore installati, nel caso in cui abbiamo dimenticato:

user> (:db.install/valueType (datomic.api/entity db :db.part/db)) 
#{:db.type/uuid :db.type/bigint :db.type/uri :db.type/ref 
    :db.type/keyword :db.type/bytes :db.type/string :db.type/instant 
    :db.type/fn :db.type/long :db.type/bigdec :db.type/boolean 
    :db.type/double :db.type/float} 

Oppure possiamo scrivere query sugli attributi esistenti:

user> (datomic.api/q '[:find ?ns (distinct ?attr) :where 
         [:db.part/db :db.install/attribute ?a] 
         [?a :db/ident ?attr] 
         [(namespace ?attr) ?ns]] 
        db) 
[["db" #{:db/noHistory :db/cardinality :db/index :db/unique 
     :db/fulltext :db/txInstant :db/lang :db/doc 
     :db/code :db/isComponent :db/fn :db/valueType 
     :db/ident}] 
["db.install" #{:db.install/partition :db.install/attribute 
       :db.install/valueType :db.install/function}] 
["fressian" #{:fressian/tag}]]