come sostituire una stringa/parola in un file di testo in Groovy

Question

Ciao Sto usando Groovy 2.1.5 e devo scrivere un codice che mostrano le Contens/file di una directory con un determinato percorso, allora si esegue un backup di il file e sostituire una parola/stringa dal file. qui è il codice che ho usato per cercare di sostituire una parola nel file selezionato

String contents = new File('/geretd/resume.txt').getText('UTF-8') 
contents = contents.replaceAll('visa', 'viva') 

anche qui è il mio codice completo se qualcuno vorrebbe modificarlo in modo più efficiente, io apprezzo da quando ho sto imparando.

def dir = new File('/geretd') 
dir.eachFile { 
    if (it.isFile()) { 
     println it.canonicalPath 
    } 
} 

copy = { File src,File dest-> 

    def input = src.newDataInputStream() 
    def output = dest.newDataOutputStream() 

    output << input 

    input.close() 
    output.close() 
} 

//File srcFile = new File(args[0]) 
//File destFile = new File(args[1]) 

File srcFile = new File('/geretd/resume.txt') 
File destFile = new File('/geretd/resumebak.txt') 
copy(srcFile,destFile) 

x = " " 
println x 

def dire = new File('/geretd') 
dir.eachFile { 
    if (it.isFile()) { 
     println it.canonicalPath 
    } 
} 

String contents = new File('/geretd/resume.txt').getText('UTF-8') 
contents = contents.replaceAll('visa', 'viva') 

Answer 1

Vedere this answer dove i modelli vengono sostituiti. Lo stesso principio può essere utilizzato per sostituire le stringhe.

Esempio

def copyAndReplaceText(source, dest, Closure replaceText){ 
    dest.write(replaceText(source.text)) 
} 

def source = new File('source.txt') //Hello World 
def dest = new File('dest.txt') //blank 

copyAndReplaceText(source, dest) { 
    it.replaceAll('World', 'World!!!!!') 
} 

assert 'Hello World' == source.text 
assert 'Hello World!!!!!' == dest.text 

Answer 2

In alternativa caricare l'intero file in memoria, si poteva fare di ogni riga, a sua volta

new File('destination.txt').withWriter { w -> 
    new File('source.txt').eachLine { line -> 
    w << line.replaceAll('World', 'World!!!') + System.getProperty("line.separator") 
    } 
} 

Naturalmente questo (e dmahapatro's answer) si basano sulle parole si sta sostituendo non si estende attraverso le linee

Answer 3

Come per quasi tutto Groovy, AntBuilder è il più facile percorso:

ant.replace(file: "myFile", token: "NEEDLE", value: "replacement") 

Answer 4

Io uso questo codice per sostituire la porta 8080 a $ {} port.http direttamente in certo file:

def file = new File('deploy/tomcat/conf/server.xml') 
    def newConfig = file.text.replace('8080', '${port.http}') 
    file.text = newConfig 

La prima stringa legge una riga del file nella variabile. La seconda stringa esegue una sostituzione. La terza stringa scrive una variabile in un file.

Answer 5

altra soluzione semplice sarebbe quella dopo la chiusura:

def replace = { File source, String toSearch, String replacement -> 
     source.write(source.text.replaceAll(toSearch, replacement)) 
    }