Sostituzione di più blocchi delimitati in sed

Question

Ho un corpo di testo che contiene gruppi delimitati da <>, ## o ||. I blocchi non si sovrappongono, ma possono attraversare più righe, in questo modo:

#A fully emphasized line# 
A line with #emphasis inside#. 
#Several lines of 
text 
With emphasis# 
no emphasis 
Line #with# multiple #emphasis#. 
Line <with some > |text of| #each type#. 

Sto tentando di sostituire ogni coppia di delimitatori con [e] e mettere il delimitatore finale dopo l']; per esempio l'ultima riga dovrebbe essere:

Line [with some ]> [text of]| [each type]#. 

ho formato uno script sed che farà la prima parte:

sed -e ':left s/[#|<]/[/; t right; n; b left :right s/[#|>]/]/; t left;n; b right' 

Ma quando provo ad usare & (o (..) + \ 1) per mettere il carattere di nuovo in questo modo:

sed -e ':left s/[#|<]/[/; t right; n; b left :right s/[#|>]/]&/; t left;n; b right' 

ottengo il seguente:

[A fully emphasized line][ 
A line with ][emphasis inside][. 
][Several lines of 
text 
With emphasis][ 
no emphasis 
Line ][with][ multiple ][emphasis][. 
Line [with some ]]]]]]> [text of[ [each type[. 

Non sono sicuro di cosa sia andato storto qui - sembra che stia aggredendo il blocco del modello in qualche modo. Potrei sostituirlo con tre chiamate (uno codificato per tipo di corrispondenza), ma sembra eccessivo.

Answer 1

Provare a seguire il comando. Si legge l'intero file in memoria e fare sostituzioni globali per ogni coppia di delimitatori:

sed -e ' 
    :a 
    $! { N; ba }; 
    s/#\([^#]*\)#/[\1]#/g; 
    s/<\([^>]*\)>/[\1]>/g; 
    s/|\([^|]*\)|/[\1]|/g 
' infile 

cede:

[A fully emphasized line]# 
A line with [emphasis inside]#. 
[Several lines of 
text 
With emphasis]# 
no emphasis 
Line [with]# multiple [emphasis]#. 
Line [with some ]> [text of]| [each type]#.