Ottieni un intervallo denominato per stringa nella cartella di lavoro di Excel quando il nome è duplicato

Question

Per elaborare, diciamo che ho due intervalli nominati nella mia cartella di lavoro. Entrambi gli intervalli denominati hanno lo stesso nome (diciamo "myName"), ma uno è limitato a Sheet1 e l'altro è ambito alla cartella di lavoro.

Dato un nome (stringa) dell'intervallo denominato, desidero accedere all'intervallo denominato livello di cartella di lavoro.

Se utilizzo la chiamata nativa: wb.Names.Item("myName"), restituisce l'intervallo denominato ambito.

Se invece lo faccio: wb.Names.Item("Sheet1!myName"), restituisce ovviamente l'intervallo del nome dell'ambito del foglio. Ho scoperto che posso usarlo per specificare quelli specifici per il foglio, ma non per quello di una cartella di lavoro.

Esiste comunque la possibilità di specificare la cartella di lavoro con scope?

La mia soluzione alternativa sta attualmente eseguendo l'iterazione nell'elenco di tutti i nomi e il confronto della proprietà .Name per acquisire l'ambito denominato Intervallo di lavoro. Funziona perché la proprietà .Name aggiunge un "Foglio1!" all'intervallo denominato ambito. Questo è comunque molto costoso da fare, e voglio evitarlo.

Answer 1

Quando noi (JKP e io) scrivevamo Name Manager abbiamo aggiunto in modo specifico un filtro e un messaggio di avviso per nomi globali/locali duplicati perché questo comportamento del modello di oggetto Excel che hai menzionato porta a errori difficili da rilevare.

Quindi la mia raccomandazione è di non usare mai nomi globali/locali duplicati.

Utilizziamo il codice per rilevare se un nome è duplicato globale/locale con il genitore del nome locale attivo e quindi passare i fogli se necessario. Il codice VBA ottimizzato che usiamo per trovare la versione locale di un nome globale è questo: la sua ragionevolmente veloce a meno che non si dispone di diverse decine di migliaia di nomi -

Function FindNameLocal(oSheet As Worksheet, sName As String) As Name 
     Dim oName As Name 
     Dim strLocalName As String 
     Dim strLocalNameNoQuote 
     Dim strName As String 
     Set FindNameLocal = Nothing 
     If Len(sName) > 0 And Not oSheet Is Nothing And oSheet.Names.Count > 0 Then 
      On Error Resume Next 
      strLocalName = "'" & oSheet.Name & "'!" & sName 
      strLocalNameNoQuote = oSheet.Name & "!" & sName 
      Set FindNameLocal = oSheet.Names(strLocalName) 
      If Err <> 0 Or (FindNameLocal.NameLocal <> strLocalName And FindNameLocal.NameLocal <> strLocalNameNoQuote) Then 
       On Error GoTo 0 
       Set FindNameLocal = Nothing 
       For Each oName In oSheet.Names 
        strName = oName.Name 
        If Len(strLocalName) = Len(strName) Or Len(strLocalNameNoQuote) = Len(strName) Then 
         If strName = strLocalName Or strName = strLocalNameNoQuote Then 
          Set FindNameLocal = oName 
          GoTo GoExit 
         End If 
        End If 
       Next 
      End If 
     End If 
GoExit: 
    End Function