Controllare il tipo di nodo nel modello XSL

Question

È possibile verificare il tipo di nodo che ho abbinato a un modello all'interno dello stesso modello? Nel caso lo sia, come posso farlo? Per esempio mi piacerebbe fare qualcosa di simile:

<xsl:template match="@*|node()"> 
    <xsl:choose> 
     <xsl:when test="current() is an attribute"> 
     <!-- ... --> 
     </xsl:when> 
     <xsl:when test="current() is an element"> 
     <!-- ... --> 
     </xsl:when> 
     <xsl:otherwise> 
     <!-- ... --> 
     </xsl:otherwise> 
    </xsl:choose> 
</xsl:template> 

Answer 1

Date un'occhiata a questa risposta qui, in quanto questo dovrebbe darvi le informazioni necessarie:

Difference between: child::node() and child::*

Questo dà il seguente xsl: scegliere per testare tutti i nodi, incluso il nodo del documento.

<xsl:choose> 
    <xsl:when test="count(.|/)=1"> 
    <xsl:text>Root</xsl:text> 
    </xsl:when> 
    <xsl:when test="self::*"> 
    <xsl:text>Element </xsl:text> 
    <xsl:value-of select="name()"/> 
    </xsl:when> 
    <xsl:when test="self::text()"> 
    <xsl:text>Text</xsl:text> 
    </xsl:when> 
    <xsl:when test="self::comment()"> 
    <xsl:text>Comment</xsl:text> 
    </xsl:when> 
    <xsl:when test="self::processing-instruction()"> 
    <xsl:text>PI</xsl:text> 
    </xsl:when> 
    <xsl:when test="count(.|../@*)=count(../@*)"> 
    <xsl:text>Attribute</xsl:text> 
    </xsl:when> 
</xsl:choose> 

Answer 2

Un modo più preciso per determinare se il nodo $node è un nodo radice:

not(count($node/ancestor::node())) 

L'espressione in risposta TimC prove, il tipo del nodo corrente:

count(.|/)=1 

ma non è applicabile nel caso in cui si voglia determinare il tipo di nodo in una variabile - che può appartenere a un altro documento - non al documento corrente.

Inoltre, un test per un nodo di spazio dei nomi:

count($node | $node/../namespace::*) = count($node/../namespace::*) 

Answer 3

consiglio vivamente di utilizzare la expressions on sequence types introduced in XPath 2.0. Ad esempio:

. instance of document-node() 
. instance of element()