Come posso forzare i nostri sviluppatori a inserire note quando si esegue il commit tramite TortoiseSVN?

Question

Spesso vedo un gran numero di commit, ma non ci sono note che facciano riferimento ai biglietti ... E così finisco per tornare indietro e rivedere la diff manualmente. Non necessariamente male, ma sarebbe bello avere delle note. Qualche idea?

Answer 1

Certo, ma come si imporranno messaggi di commit non-gibberish, significativi e contestualizzati?

Meglio dare un pugno ai tuoi colleghi irresponsabili quando noti un commit zoppo/vuoto. O l'equivalente verbale del punch. Assicurati che si sentano male, è meritato.

Answer 2

È possibile definire uno script di hook pre-commit che rifiuta tutti i commit con un messaggio di log vuoto o troppo corto.

Ecco un post su come farlo.

Answer 3

Ho usato uno script di hook pre-commit per garantire che un commento di commit faccia sempre riferimento a un numero di problema nel sistema di tracciamento del problema. Ad esempio, un commento come

fixes frobulator when the moon is full (bug 1234)

sarebbe accettato perché contiene un numero di errore. Anche con questo accordo, devi ancora fidarti dello sviluppatore per inserire un commento e un numero di bug significativi.

Answer 4

nostra procedura di pre-commit hookscript (finestre batch):

@echo off & setlocal ENABLEEXTENSIONS 

set SVNLOOK="E:\Subversion\Program\Subversion 1.5.0\bin\svnlook.exe" 

set REPOS=%1% 
set TXN=%2% 
set LOGFILE=%REPOS%\hooks\log-%TXN%.txt 
set GREP=E:\UnxUtils\usr\local\wbin\grep.exe 

%SVNLOOK% log -t "%TXN%" "%REPOS%" >%LOGFILE% 

set "first=" 
for /f "delims=" %%a in ('more ^< "%LOGFILE%"') do (
    if not defined first set first=%%a 
) 

del %LOGFILE% 

if not defined first (echo "Please supply a commit comment" >&2 & exit 1) 





REM Check for invalid windows characters in the path 
echo Checking >%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "\" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find ":" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "*" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "?" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find """" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^>" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^<" >>%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^|" >>%LOGFILE% 

set "first=" 
for /f "delims=" %%a in ('more +1 ^< "%LOGFILE%"') do (
    if not defined first set first=%%a 
) 

del %LOGFILE% 

if defined first (echo "Please do not use filename characters which are invalid in windows. - Found %first%" >&2 & exit 1) 






REM Tagblock - prevent changes to tag directories 
echo Checking >%LOGFILE% 
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | %GREP% "^U.*\/tags\/.*" | %GREP% -v -f "%REPOS%\conf\tag-block-exceptions.txt" >>%LOGFILE% 

set "first=" 
for /f "delims=" %%a in ('more +1 ^< "%LOGFILE%"') do (
    if not defined first set first=%%a 
) 

del %LOGFILE% 


if defined first ( 
    echo "%first% -- Error: Modifications to tag directories are blocked. To allow these modifications add the path to %REPOS%\conf\tag-block-exceptions.txt" >&2 
    exit 1) 

Answer 5

Non TortoiseSVN, ma Subversion stesso - un'impostazione sul server. È possibile impostare un hook di pre-commit che impone un commento di commit. Esistono anche hook pre-commit che verificheranno la presenza di un riferimento a un sistema di tracciamento di problemi come Jira se si vuole fare un ulteriore passo avanti.

Answer 6

TortoiseSVN è un client, è possibile che si desideri force comments on the subversion server. Oppure puoi dire loro di commentare i loro commit.

Answer 7

È necessario utilizzare un hook di pre-commit che è un'impostazione del server, ne ho scritto uno per VisualSVN che è fondamentalmente un file batch - sono disponibili script simili per server SVN non basati su Windows.

@echo off 
:: 
:: Stops commits that have empty log messages. 
:: 
@echo off 
setlocal 

rem Subversion sends through the path to the repository and transaction id 
set REPOS=%1 
set TXN=%2 

rem check for an empty log message 
call "C:\program files\visualsvn server\bin\svnlook" log %REPOS% -t %TXN% | findstr . > nul 
if %errorlevel% gtr 0 (goto err) else exit 0 

:err 
echo. 1>&2 
echo Your commit has been blocked because you didn't give any log message 1>&2 
echo Please write a log message describing the purpose of your changes and 1>&2 
echo then try committing again. -- Thank you 1>&2 
exit 1 

Answer 8

È possibile forzare un commettere commento abbastanza facilmente, ma quello che vi ritroverete con un milione di commit è che dicono "debug" o "testing".

Se i tuoi sviluppatori non vedono il valore nell'aggiunta di messaggi di commit che li costringono a digitare qualcosa che non è stato modificato da.

Ciò che è peggio è quando gli utenti di Eclipse hanno integrato SVN/CVS in modo tale da ricordare il loro ultimo messaggio di commit - e finiscono per commettere un file completamente non correlato con il messaggio dall'ultima attività/progetto.