Come posso utilizzare Proc SQL per trovare tutti i record che esistono solo in una tabella ma non nell'altra?

Question

Sto provando a farlo in Enterprise Guide, con un'attività, altrimenti userei solo un passaggio di dati.

In una fase dati, questo sarebbe:

data names; 
input name $; 
datalines; 
    John 
    Mary 
    Sally 
    Fred 
    Paul 
; 
run; 

data check; 
input name $; 
datalines; 
    Mary 
    Fred 
; 

Proc sort data=names; by name; run; 
Proc sort data=check; by name; run; 

Data work.not_in_check; 
merge names(in=n) check(in=c); 
by name; 
if n and not c; 
run; 

Answer 1

Ecco un modo. Ce ne sono sicuramente molti altri.

proc sql; 
create table not_in_check as 
select name 
from names 
where name not in (select name from check); 
quit; 

Answer 2

Un'altra leggera variazione è:

proc sql; 
create table not_in_check as select 
a.* from names as a left join 
      check as b on 
      a.name=b.name 
      where b.name is null; 
quit; 

Answer 3

proc sql; 
create table inNamesNotIncheck 
as 
select * 
from names n 
where not exists 
(select name 
from check c 
where n.name=c.name); 
quit; 

Answer 4

Il seguente metodo è il modo piuttosto semplice per ottenere i record presenti in una tabella e non nell'altra.

tabella creata nuovo con i record che contengono Sesso = M, il risultato dopo l'interrogazione sarà record con il sesso = F.

Esempio:

data new; 
set sashelp.class; 
where sex = 'M'; 
run; 
proc sql; 
create table new1 as 
select * from sashelp.class 
except all 
select * from new; 
quit; 

metterà il codice per verificare il mio set di dati effettivi che sono di circa 100k obs e aggiornano il risultato.

P.S: so che la domanda è stata posta risposta e dimenticata, stavo cercando un modo per fare quanto sopra e non riuscivo a trovare una risposta diretta dove. Quindi, aggiungendo in modo che possa tornare utile. :)

Anche la mia prima risposta. :)