Assegna il codice a un pulsante creato dinamicamente

Question

Sto cercando di ottenere un pulsante che ho creato dinamicamente su un modulo utente excel per eseguire una macro denominata transfer che ho scritto in Module 1 della sezione "Moduli" del mio progetto .

Qui di seguito ho incollato il codice che ho scritto finora nel userform che gestisce in realtà per creare il pulsante Transfer to Sheet nel telaio (che ho anche creato dinamicamente), ma per qualche ragione, quando corro VBA Ottengo un messaggio 438 error dicendo che Object doesn't support this property or method.

Qualcuno può dirmi come posso risolvere questo?

Ecco il codice:

Dim framecontrol1 As Control 

Set workitemframe = Controls.Add("Forms.Frame.1") 
With workitemframe 
    .Width = 400 
    .Height = 400 
    .Top = 160 
    .Left = 2 
    .ZOrder (1) 
    .Visible = True 
End With 

workitemframe.Caption = "Test" 
Set framecontrol1 = workitemframe.Controls.Add("Forms.commandbutton.1") 

With framecontrol1 
    .Width = 100 
    .Top = 70 
    .Left = 10 
    .ZOrder (1) 
    .Visible = True 
    .Caption = "Transfer to Sheet" 
End With 
framecontrol1.OnAction = "transfer" 

Answer 1

Ecco un esempio. Si prega di modificarlo in base alle proprie esigenze :)

Questo esempio creerà un pulsante di comando e assegnerà il codice ad esso in modo che quando viene premuto, verrà visualizzato "Hello World".

Incollare questo codice nell'evento click di un pulsante di comando che creerà dinamicamente un nuovo pulsante di comando e assegnerà il codice ad esso.

Option Explicit 

Dim cmdArray() As New Class1 

Private Sub CommandButton1_Click() 
    Dim ctl_Command As Control 
    Dim i As Long 

    i = 1 

    Set ctl_Command = Me.Controls.Add("Forms.CommandButton.1", "CmdXYZ" & i, False) 

    With ctl_Command 
     .Left = 100 
     .Top = 100 
     .Width = 255 
     .Caption = "Click Me " & CStr(i) 
     .Visible = True 
    End With 

    ReDim Preserve cmdArray(1 To i) 
    Set cmdArray(i).CmdEvents = ctl_Command 

    Set ctl_Command = Nothing 

End Sub 

e incollare questo codice in un modulo di classe

Option Explicit 

Public WithEvents CmdEvents As MSForms.CommandButton 

Private Sub CmdEvents_Click() 

    MsgBox "Hello Word" 

End Sub 

ISTANTANEA

Answer 2

È necessario aggiungere il codice al form utente programatically. Ho usato il mio codice da questo vbax article come riferimento

Il codice qui sotto:

1. viene eseguito da un modulo normale
2. Aggiunge il pulsante per un form chiamato UserForm1

3. aggiunge questo codice l'Userform per un evento Click

   Private Sub CommandButton1_Click() 
   Call Transfer 
   End Sub 
   

VBA dal modulo normale

Sub AddToForm() 
    Dim UF As Object 
    Dim frameCOntrol1 As Object 
    Set UF = ActiveWorkbook.VBProject.VBComponents("UserForm1") 
    Set frameCOntrol1 = UF.designer.Controls.Add("Forms.CommandButton.1") 
    With frameCOntrol1 
     .Width = 100 
     .Top = 70 
     .Left = 10 
     .ZOrder (1) 
     .Visible = True 
     .Caption = "Transfer to Sheet" 
    End With 

    With UF.CodeModule 
     .InsertLines 2, _ 
        "Private Sub " & frameCOntrol1.Name & "_Click()" & Chr(13) & _ 
        "Call Transfer" & Chr(13) & _ 
        "End Sub" 
    End With 

End Sub