Come rendere il comportamento di zsh forward-word come in bash/emacs

Question

zsh forward-word si comporta in modo un po 'diverso da bash/emacs, e mi piacerebbe cambiarlo.

Invece di una descrizione di tutte le differenze, lascia che ti mostri il comportamento passo passo di bash. Ho contrassegnato il cursore come simbolo "^".

foo bar --non-needed-param --needed-param^ 

M-b

foo bar --non-needed-param --needed-^param 

M-b

foo bar --non-needed-param --^needed-param 

M-b

foo bar --non-needed-^param --needed-param 

M-b

foo bar --non-^needed-param --needed-param 

M-b

foo bar --^non-needed-param --needed-param 

M-b

foo ^bar --non-needed-param --needed-param 

M-f

foo bar^ --non-needed-param --needed-param 

M-d

foo bar^-needed-param --needed-param 

M-d

foo bar^-param --needed-param 

M-d

foo bar^ --needed-param 

Questo algoritmo è sia flessibile per muoversi attraverso parole, rimuovendo parti di loro per me. Inoltre è in emacs, quindi ci sono abituato. Mi piacerebbe vederlo anche in zsh. Grazie.

Answer 1

ho questo nel mio .zshrc esattamente per questo scopo:

# Bash-like navigation 
autoload -U select-word-style 
select-word-style bash 

Edit: Ah, mi ricordo quello che mancava per far funzionare tutto come volevo. Ho anche sovrascritto forward-word-match inserendo la seguente contenuto in $ZDOTDIR/functions/forward-word-match (supponendo che il directory $ZDOTDIR/functions è in $fpath, altrimenti metterlo in uno o modificare la matrice $fpath pure):

emulate -L zsh 
setopt extendedglob 

autoload match-words-by-style 

local curcontext=":zle:$WIDGET" word 
local -a matched_words 
integer count=${NUMERIC:-1} 

if ((count < 0)); then 
    ((NUMERIC = -count)) 
    zle ${WIDGET/forward/backward} 
    return 
fi 

while ((count--)); do 

    match-words-by-style 

    # For some reason forward-word doesn't work like the other word 
    # commands; it skips whitespace only after any matched word 
    # characters. 

    if [[ -n $matched_words[4] ]]; then 
     # just skip the whitespace and the following word 
    word=$matched_words[4]$matched_words[5] 
    else 
     # skip the word but not the trailing whitespace 
    word=$matched_words[5] 
    fi 

    if [[ -n $word ]]; then 
    ((CURSOR += ${#word})) 
    else 
    return 1 
    fi 
done 

return 0