clojure: aggiunta una traccia di debug ad ogni funzione in un namespace?

Question

ha appena iniziato a utilizzare log4j in uno dei miei progetti di casa e stavo proprio per rompere il mouse e tagliare e incollare (trace (str "entering: " function-name)) in ogni funzione in un modulo di grandi dimensioni. poi la voce della ragione è arrivata e ha detto "semplicemente deve esserci un modo migliore" ... Posso pensare di creare una macro che avvolge un intero blocco di funzioni e aggiunge le tracce a loro o qualcosa del genere? Qualche consiglio dai saggi clojuriani stracolmi di pila?

Answer 1

Non c'è bisogno di una macro:

(defn trace-ns 
    "ns should be a namespace object or a symbol." 
    [ns] 
    (doseq [s (keys (ns-interns ns)) 
      :let [v (ns-resolve ns s)] 
      :when (and (ifn? @v) (-> v meta :macro not))] 
    (intern ns 
      (with-meta s {:traced true :untraced @v}) 
      (let [f @v] (fn [& args] 
          (clojure.contrib.trace/trace (str "entering: " s)) 
          (apply f args)))))) 

(defn untrace-ns [ns] 
    (doseq [s (keys (ns-interns ns)) 
      :let [v (ns-resolve ns s)] 
      :when (:traced (meta v))] 
    (alter-meta! (intern ns s (:untraced (meta v))) 
       #(dissoc % :traced :untraced)))) 

... o qualcosa di simile. Il requisito aggiuntivo più probabile sarebbe quello di utilizzare filter in modo da non chiamare trace su cose che non sono ifn? s. Aggiornamento: modificato in una soluzione (anche gestendo macro). Aggiornamento 2: corretto alcuni bug importanti. Aggiornamento 4: aggiunta funzionalità di annullamento.

Update 3: Ecco un esempio dalla mia REPL:

user> (ns foo) 
nil 
foo> (defn foo [x] x) 
#'foo/foo 
foo> (defmacro bar [x] x) 
#'foo/bar 
foo> (ns user) 
nil 
user> (trace-ns 'foo) 
nil 
user> (foo/foo :foo) 
TRACE: "entering: foo" 
:foo 
user> (foo/bar :foo) 
:foo 
user> (untrace-ns 'foo) 
nil 
user> (foo/foo :foo) 
:foo