Come posso ottenere un elenco di tutti i file con una determinata estensione da una directory specifica?

Question

Sto usando questo codice per ottenere un elenco di tutti i file in una directory specifica:

opendir DIR, $dir or die "cannot open dir $dir: $!"; 
my @files= readdir DIR; 
closedir DIR; 

Come posso modificare il codice o aggiungere qualcosa ad esso in modo che appaia solo per i file di testo e solo carichi la matrice con il prefisso del nome file?

contenuto della directory Esempio:

. 
.. 
923847.txt 
98398523.txt 
198.txt 
deisi.jpg 
oisoifs.gif 
lksdjl.exe 

Esempio contenuto dell'array:

files[0]=923847 
files[1]=98398523 
files[2]=198 

Answer 1

my @files = glob "$dir/*.txt"; 
for (0..$#files){ 
    $files[$_] =~ s/\.txt$//; 
} 

Answer 2

è sufficiente a cambiare una sola riga:

my @files= map{s/\.[^.]+$//;$_}grep {/\.txt$/} readdir DIR; 

Answer 3

per ottenere solo il". txt ", puoi usare un file test oper ator (-f: file normale) e una regex.

my @files = grep { -f && /\.txt$/ } readdir $dir; 

In caso contrario, è possibile cercare i file di testo solo, utilizzando (operatore di verifica file di testo ASCII) -T di perl

my @files = grep { -T } readdir $dir; 

Answer 4

Se è possibile utilizzare le nuove funzionalità di Perl 5.10, questo è il modo Lo scriverei

use strict; 
use warnings; 
use 5.10.1; 
use autodie; # don't need to check the output of opendir now 

my $dir = "."; 

{ 
    opendir my($dirhandle), $dir; 
    for(readdir $dirhandle){ # sets $_ 
    when(-d $_){ next } # skip directories 
    when(/^[.]/){ next } # skip dot-files 

    when(/(.+)[.]txt$/){ say "text file: ", $1 } 
    default{ 
     say "other file: ", $_; 
    } 
    } 
    # $dirhandle is automatically closed here 
} 

O se avete grosse directory, è possibile utilizzare un ciclo while.

{ 
    opendir my($dirhandle), $dir; 
    while(my $elem = readdir $dirhandle){ 
    given($elem){ # sets $_ 
     when(-d $_){ next } # skip directories 
     when(/^[.]/){ next } # skip dot-files 

     when(/(.+)[.]txt$/){ say "text file: ", $1 } 
     default{ 
     say "other file: ", $_; 
     } 
    } 
    } 
} 

Answer 5

Basta usare questo:

my @files = map {-f && s{\.txt\z}{} ? $_ :()} readdir DIR; 

Answer 6

Questo è il modo più semplice che ho trovato (come nel leggibile) utilizzando la funzione glob:

# Store only TXT-files in the @files array using glob 
my @files = grep (-f ,<*.txt>); 
# Write them out 
foreach $file (@files) { 
    print "$file\n"; 
} 

Inoltre il "-f "assicura che solo i file effettivi (e non le directory) siano memorizzati nell'array.