Transpose in perl

Question

Ho iniziato a imparare perl e mi piace provare nuove cose.

Ho qualche problema nell'elaborazione del testo. ho qualche testo del modulo,

0 1 2 3 4 5 6 7 8 9 10 

6 7 3 6 9 3 1 5 2 4 6 

voglio trasporre questo testo. Ad esempio, voglio creare righe come colonne e colonne come righe. Id c'è un modo per farlo in perl?

Grazie a tutti.

Answer 1

Quindi questa soluzione utilizza un array di array, ogni array nidificato è una riga di dati. Molto semplicemente si esegue il ciclo sulle colonne in ciascuna riga e le si inserisce su un altro array di array utilizzando l'indice della colonna come indice su cui inserire il valore. Questo ha l'effetto di ruotare i dati come richiesto.

#!/usr/bin/env perl 

my @rows =(); 
my @transposed =(); 

# This is each row in your table 
push(@rows, [qw(0 1 2 3 4 5 6 7 8 9 10)]); 
push(@rows, [qw(6 7 3 6 9 3 1 5 2 4 6)]); 

for my $row (@rows) { 
    for my $column (0 .. $#{$row}) { 
    push(@{$transposed[$column]}, $row->[$column]); 
    } 
} 

for my $new_row (@transposed) { 
    for my $new_col (@{$new_row}) { 
     print $new_col, " "; 
    } 
    print "\n"; 
} 

Questo si traduce in:

0 6 
1 7 
2 3 
3 6 
4 9 
5 3 
6 1 
7 5 
8 2 
9 4 
10 6 

Answer 2

C'è sicuramente, e Mike ha indicato il modo più semplice. Se stai imparando, probabilmente vuoi scrivere la tua funzione?
In primo luogo, si vuole split ogni riga su spazi per ottenere un array di valori (o push la list of words nella matrice, come in Dalton's answer, in Perl, c'è sempre più di un modo per fare qualcosa)
Poi, for each element in the array, vuoi stamparlo e la sua controparte nel secondo array sulla stessa linea. (Cosa farai se un array finisce prima dell'altro?)

Ovviamente, se vuoi imparare Perl, vorrai anche imparare ad usare anche CPAN, quindi vale ancora la pena provare a usare Data ::Perno.

Answer 3

Ecco uno schema di un modo per trasporre i dati. Lavorare attraverso questo esempio sarà istruttivo perché dovrai usare CPAN, imparerai a conoscere i moduli utili List::Util e List::MoreUtils, imparerai le basi delle strutture di dati complesse (vedi perlreftut, perldsc e perllol), e arriverete a usa un iteratore in Perl.

use strict; 
use warnings; 
use List::MoreUtils qw(each_arrayref); 

my @raw_data = (
    '0 1 2 3 4 5 6 7 8 9 10', 
    '6 7 3 6 9 3 1 5 2 4 6', 
); 

my @rows = ... ; # Look up map() and split() to fill in the rest. 
       # You want an array of arrays. 

my @transposed; # You will build this in the loop below. 

my $iter = each_arrayref(@rows); # See List::MoreUtils documentation. 

while (my @tuple = $iter->()){ 
    # Do stuff here to build up @transposed, which 
    # will also be an array of arrays. 
} 

Answer 4

use strict; 
# read the first line 
my @labels = split ' ', <>; 
# read and ignore the empty second line 
<>; 
# read the third line 
my @values = split ' ', <>; 
# transpose (I suppose you'll do more with the table than just printing it) 
my %table = map { $labels[$_] => $values[$_] } 0..$#labels; 
# print 
foreach (@labels) { 
    print "$_ $table{$_}\n"; 
} 

Answer 5

Ecco il mio nuovo script di trasporre un file delimitato da tabulazioni. Cambia \ t al tuo delimitatore, se lo desideri.

#!/usr/bin/perl -anF/\t|\n/ 
$n = @F - 1 if !$n; 
for $i (0..$n) { 
    push @{ $m->[$i] }, $F[$i]; 
} 
END { 
    for $r (@$m) { 
     print join("\t", @$r), "\n"; 
    } 
} 

o come un carattere 104 "un liner" (con apostrofo-backslash-newline apostrofo aggiunta per evitare lo scorrimento orizzontale):

perl -anF'\t|\n' -e'$n=@F-1if!$n;for(0..$n){push@{$$m[$_]},$F[$_]}'\ 
'END{print map{join"\t",@$_,"\n"}@$m}' 

Answer 6

come su array-Trasposizione-0,06?

http://metacpan.org/pod/Array::Transpose

Answer 7

use List::UtilsBy qw/zip_by/; 

my @transposition = zip_by { [ @_ ] } @matrix; 

https://metacpan.org/pod/List::UtilsBy#zip_by

Answer 8

use strict; 
my ($i, $rows, $cols) = (0, 10, 100); 
# initiate array 10x100 
my $array = [map {[map {$i++} (1..$cols)]} (1..$rows)]; 
# transpose array into 100x10 array 
my $transpose = [map {[map {shift @$_} @$array]} @{$array->[0]}]; 

array deve essere una matrice, cioè le colonne devono essere uguali per ogni riga, array originale viene distrutto

questo codice non userà supplementare memoria per transpose, x2 per altre librerie, per array di grandi dimensioni ad esempio 100x1M, è importante