VirtualTreeView - colore diverso di testo nello stesso nodo

Question

Sto tentando di creare una vista in TVirtualStringTree che sarà simile a qualcosa di simile:

Nell'esempio precedente ho mostrato alcuni dei possibili scenari che voglio raggiungere. FolderA ha il testo in grassetto e dopo il testo in grassetto di colore rosso appena dietro di esso nello stesso nodo. Sto cercando il modo di realizzare questo tipo di output.

Tuttavia, se questo è troppo duro o troppo problematico per creare, sarei felice con FolderB o FolderC tipo di output - che potrebbe probabilmente essere fatta con 2 colonne, una contenente il nome della cartella e un altro contenente il conteggio dei file all'interno.

FolderD è qui solo come esempio di una cartella senza file e l'output per quella cartella (il testo è non piegato e non c'è numero).

Sto cercando tutte le indicazioni su come effettuare questo effetto in quanto sembra che VirtualTreeView possa avere solo un colore o un'impostazione grassetto per un nodo. Qualsiasi suggerimento o suggerimento su come spostarsi nella direzione di FolderA o FolderB o FolderC molto apprezzato quindi ho un punto di partenza. Gli esempi di Delphi o C++ Builder sono entrambi benvenuti (il codice finale sarà comunque in C++ Builder).

Answer 1

Si potrebbe semplicemente utilizzare il toShowStaticText (StringOptions) opzione:

implementation 

type 
    PNodeRec = ^TNodeRec; 
    TNodeRec = record 
    Name: WideString; 
    Count: Integer; 
    IsBold: Boolean; 
    end; 

procedure TForm1.FormCreate(Sender: TObject); 
var 
    Node: PVirtualNode; 
    NodeRec: PNodeRec; 
    I: Integer; 
begin 
    VirtualStringTree1.TreeOptions.StringOptions := 
    VirtualStringTree1.TreeOptions.StringOptions + [toShowStaticText]; 
    VirtualStringTree1.NodeDataSize := Sizeof(TNodeRec); 
    // Populate some data 
    for I := 1 to 10 do 
    begin 
    Node := VirtualStringTree1.AddChild(nil); 
    NodeRec := VirtualStringTree1.GetNodeData(Node); 
    Initialize(NodeRec^); 
    NodeRec.Name := 'Node' + IntToStr(I); 
    NodeRec.Count := I; 
    NodeRec.IsBold := I mod 2 = 0; 
    end; 
end; 

procedure TForm1.VirtualStringTree1GetText(Sender: TBaseVirtualTree; 
    Node: PVirtualNode; Column: TColumnIndex; TextType: TVSTTextType; 
    var CellText: WideString); 
var 
    NodeRec: PNodeRec; 
begin 
    NodeRec := PNodeRec(TVirtualStringTree(Sender).GetNodeData(Node)); 
    if TextType = ttNormal then 
    CellText := NodeRec^.Name 
    else // ttStatic 
    CellText := Format('(%d)', [NodeRec^.Count]); 
end; 

procedure TForm1.VirtualStringTree1PaintText(Sender: TBaseVirtualTree; 
    const TargetCanvas: TCanvas; Node: PVirtualNode; Column: TColumnIndex; 
    TextType: TVSTTextType); 
var 
    NodeRec: PNodeRec; 
begin 
    NodeRec := PNodeRec(TVirtualStringTree(Sender).GetNodeData(Node)); 
    if TextType = ttNormal then 
    begin 
    if NodeRec^.IsBold then 
     TargetCanvas.Font.Style := TargetCanvas.Font.Style + [fsBold]; 
    end 
    else // ttStatic 
    TargetCanvas.Font.Color := clRed; 
end; 

uscita: