Valore variabile predefinito XSLT se il valore non è presente

Question

Sto tentando di dichiarare una variabile che ha un valore predefinito o se un valore è presente in un set ripetuto per utilizzare un nuovo valore diverso.

Questo è quello che ho finora.

 <xsl:variable name="lsind"> 
     <xsl:value-of select="'N'"/> 

     <xsl:for-each select='./Plan/InvestmentStrategy/FundSplit'> 
      <xsl:choose> 
      <xsl:when test="contains(./@FundName, 'Lifestyle')"> 
       <xsl:value-of select="'Y'"/> 
      </xsl:when> 
      </xsl:choose> 
     </xsl:for-each> 
     </xsl:variable> 

Quello che voglio è che se tutte le istanze di ./Plan/InvestmentStrategy/FundSplit/@FundName 'contiene' Stile poi lsind 'Y' in caso contrario passa al valore predefinito di 'N'.

Lo sto facendo in questo modo, come se io usassi "altrimenti l'ultima ricorrenza potrebbe potenzialmente tornare a N?

Qualche suggerimento?

Answer 1

<xsl:variable name="lsind"> 
    <xsl:choose> 
    <xsl:when test="Plan/InvestmentStrategy/FundSplit[contains(@FundName, 'Lifestyle')]"> 
     <xsl:text>Y</xsl:text> 
    </xsl:when> 
    <xsl:otherwise> 
     <xsl:text>N</xsl:text> 
    </xsl:otherwise> 
    </xsl:choose> 
</xsl:variable> 

dovrebbe essere sufficiente

Answer 2

Questo può essere specificato in un'unica espressione XPath (anche in XPath 1.0):

<xsl:variable name="vLsind" select= 
"substring('YN', 
      2 - boolean(plan/InvestmentStrategy/FundSplit[@FundName='Lifestyle']), 
      1)"/> 

Esempio 1:

<plan> 
<InvestmentStrategy> 
    <FundSplit FundName="Lifestyle"/> 
</InvestmentStrategy> 
</plan> 

Trasformazione:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:variable name="vLsind" select= 
"substring('YN', 
      2 - boolean(plan/InvestmentStrategy/FundSplit[@FundName='Lifestyle']), 
      1)"/> 

<xsl:template match="/"> 
    <xsl:value-of select="$vLsind"/> 
</xsl:template> 
</xsl:stylesheet> 

Risultato:

Y 

Esempio 2:

<plan> 
<InvestmentStrategy> 
    <FundSplit FundName="No Lifestyle"/> 
</InvestmentStrategy> 
</plan> 

Risultato:

N 

Spiegazione:

1. Per definizione boolean(some-node-set) è true() esattamente quando some-node-set è non vuoto.

2. Per definizione number(true()) è 1 e number(false()) è 0

3. 1 e 2 cobined ci dà: number(boolean(some-node-set)) è 1 esattamente quando some-node-set non è vuota, altrimenti è 0.

Altre soluzioni single-espressione:

XPath 1.0:

translate(number(boolean(YourXPathExpression)), '10', 'YN') 

XPath 2.0:

if(YourXPathExpression) 
then 'Y' 
else 'N' 

O anche:

('N', 'Y')[number(boolean(YourXPathExpression)) +1]