Come posso ottenere anche l'indice di un elemento quando eseguo il grep attraverso un array?

Question

Diciamo che ho questa lista:

my @list = qw(one two three four five); 

e voglio prendere tutti gli elementi che contengono o. Avrei questo:

my @containing_o = grep { /o/ } @list; 

Ma quello che avrei dovuto fare per ricevere anche un indice, o per essere in grado di accedere l'indice nel corpo grep s'?

Answer 1

 

my @index_containing_o = grep { $list[$_] =~ /o/ } 0..$#list; # ==> (0,1,3) 

my %hash_of_containing_o = map { $list[$_]=~/o/?($list[$_]=>$_):() } 0..$#list 
      # ==> ('one' => 0, 'two' => 1, 'four' => 3) 

Answer 2

Date un'occhiata a List::MoreUtils. Si può fare un sacco di cose a portata di mano con gli array senza dover rotolare la propria versione, in più è più veloce (perché è implementato in C/XS):

use List::MoreUtils qw(first_index indexes); 

my $index_of_matching_element = first_index { /o/ } @list; 

Per tutti gli indici corrispondenti, e poi i loro elementi corrispondenti, è possibile fare:

my @matching_indices = indexes { /o/ } @list; 
my @matching_values = @list[@matching_indices]; 

o semplicemente:

my @matching_values = grep { /o/ } @list; 

Answer 3

Questo popola 2 campi con ciò che si vuole, scorrendo la matrice di ingresso una volta:

use strict; 
use warnings; 
my @list = qw(one two three four five); 
my @containing_o; 
my @indexes_o; 
for (0 .. $#list) { 
    if ($list[$_] =~ /o/) { 
     push @containing_o, $list[$_]; 
     push @indexes_o , $_; 
    } 
}