ordinamento per mmyy (mese e anno)

Question

Sto cercando un modulo logico (non aggiuntivo) da ordinare in base a tale formato. Ho una lista di stringhe che si presenta come:

asdadasBBBsfasdasdas-0112 
asdanfnfnfnfnf222ads-1210 

ecc I cant appena sorta dai numeri, perché, ad esempio: 812> 113 (812 = Agosto 2012, 113 = gennaio 2013, quindi la sua non corretta)

qualsiasi buona strategia ??

grazie,

Answer 1

Un Trasformata di Schwartz sarebbe uno spreco enorme qui. Questo simile costrutto il cui nome non potrò mai ricordare sarebbe molto meglio.

my @sorted = 
    map substr($_, 4), 
    sort 
    map substr($_, -2) . substr($_, -4, 2) . $_, 
     @unsorted; 

Utilizzando l'operatore partita invece di substr:

my @sorted = 
    map substr($_, 4), 
    sort 
    map { /(..)(..)\z/s; $2.$1.$_ } 
     @unsorted; 

Answer 2

utilizza una funzione di ordinamento che guarda l'anno prima, e poi la data:

sub mmyy_sorter { 

    my $a_yy = substr($a, -2); 
    my $b_yy = substr($b, -2); 

    my $a_mm = substr($a, -4, 2); 
    my $b_mm = substr($b, -4, 2); 

    return ($a_yy cmp $b_yy) || ($a_mm cmp $b_mm); 
} 

my @sorted = sort mmyy_sorter @myarray; 

NB: questo è tecnicamente non così efficace come potrebbe essere in quanto ha per ricalcolare i sottocampi del mese e dell'anno per ogni confronto, non solo una volta per ciascun elemento nell'array.

Sarebbe anche possibile sfruttare la conversione di tipo automatico di Perl e utilizzare l'operatore <=> al posto di cmp, poiché tutti i valori rappresentano effettivamente numeri.

Answer 3

Che ne dici di rifarlo a mesi? Per esempio:

812 = 12 * 12 + 8

113 = 13 * 12 + 1

È possibile trasformare anni in mesi e sarà un bene. Per selezionare i numeri è possibile utilizzare regex.

Answer 4

Come su Schwartzian transform:

#!/usr/bin/perl 
use strict; 
use warnings; 
use Data::Dump qw(dump); 

my @list = (
    'asdadasBBBsfasdasdas-0112', 
    'asdanfnfnfnfnf222ads-1210', 
    'asdanfnfnfnfnf222ads-1211', 
    'asdanfnfnfnfnf222ads-1010', 
    'asdanfnfnfnfnf222ads-1011', 
); 

my @sorted = 
    map { $_->[0] } 
    sort { $a->[1] <=> $b->[1] or $a->[2] <=> $b->[2] } 
    map { /-(\d\d)(\d\d)$/; [$_, $2, $1] } @list; 
dump @sorted; 

uscita:

(
    "asdanfnfnfnfnf222ads-1010", 
    "asdanfnfnfnfnf222ads-1210", 
    "asdanfnfnfnfnf222ads-1011", 
    "asdanfnfnfnfnf222ads-1211", 
    "asdadasBBBsfasdasdas-0112", 
) 

Answer 5

Grazie a @ M42 per i dati di esempio.

use strict; 
use warnings; 
use feature 'say'; 

my @list = (
    'asdadasBBBsfasdasdas-0112', 
    'asdanfnfnfnfnf222ads-1210', 
    'asdanfnfnfnfnf222ads-1211', 
    'asdanfnfnfnfnf222ads-1010', 
    'asdanfnfnfnfnf222ads-1011', 
); 

my @sorted = sort { 
    my ($aa, $bb) = map { /(..)(..)\z/ and $2.$1 } $a, $b; 
    $aa <=> $bb; 
} @list; 

say for @sorted; 

uscita

asdanfnfnfnfnf222ads-1010 
asdanfnfnfnfnf222ads-1210 
asdanfnfnfnfnf222ads-1011 
asdanfnfnfnfnf222ads-1211 
asdadasBBBsfasdasdas-0112