Come posso modificare la didascalia di un modulo modale senza accesso alla fonte?

Question

Ho un componente di terze parti che visualizza un modulo di anteprima di stampa. Vorrei cambiare la didascalia del modulo di anteprima in qualcosa di più appropriato. Purtroppo non ho la fonte per il componente di terze parti e il componente non fornisce la funzionalità.

È possibile in qualche modo catturare il modulo modale mentre viene visualizzato e impostarne le proprietà prima che venga visualizzato?

Answer 1

Il modulo modale causa la disattivazione del modulo di chiamata, è possibile ascoltare i messaggi WM_ACTIVATE nel modulo che è attivo prima che venga visualizzato il modulo modale. Avrai l'handle della finestra di attivazione nel gestore di messaggi, puoi testarlo se è di una forma del tipo del modulo modale. Sotto test di esempio per il nome della classe, che puoi ottenere con qualcosa come Spy ++. Si noti che la disattivazione avviene brevemente dopo che la forma modale è diventata visibile, ma non penso che sarebbe possibile notare la didascalia diversa.

type 
    TForm1 = class(TForm) 
    .. 
    protected 
    procedure WMActivate(var Message: TWMActivate); message WM_ACTIVATE; 
    end; 

procedure TForm1.WMActivate(var Message: TWMActivate); 
var 
    Form: TWinControl; 
begin 
    if Message.Active = WA_INACTIVE then begin 
    Form := FindControl(Message.ActiveWindow); 
    if Form is TCustomForm then begin 
     if TCustomForm(Form).ClassName = 'TThirdPartyModalForm' then 
     TCustomForm(Form).Caption := 'My caption'; 
    end; 
    end; 
    inherited; 
end; 

Answer 2

È possibile installare un gancio WH_CBT utilizzando la funzione SetWindowsHookEx.

var 
hhk: HHOOK; 


function CBT_FUNC(nCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall; 
const 
    ClassNameBufferSize = 1024; 
var 
hTemp : HWND; 
i  : Integer; 
RetVal : Integer; 
ClassNameBuffer: Array[0..ClassNameBufferSize-1] of Char; 
begin 
    case nCode of 
    HCBT_ACTIVATE: 
    begin 
     hTemp := HWND(wParam); 
     if (Screen<>nil) and (hTemp>0) then 
     begin 
      RetVal := GetClassName(wParam, ClassNameBuffer, SizeOf(ClassNameBuffer)); 
      //check for the class 
      if (RetVal>0) and SameText(ClassNameBuffer,'TForm2') then 
      begin 
      Assert(RetVal < ClassNameBufferSize, 'Class name larger than fixed buffer size'); 
      for i := 0 to Screen.FormCount-1 do 
      if Screen.Forms[i].Handle=hTemp then 
       begin 
        //set the caption 
        Screen.Forms[i].Caption:='Hello'; 
        Break; 
       end; 
      end; 
     end; 
    end; 
    end; 
    Result := CallNextHookEx(hhk, nCode, wParam, lParam); 
end; 

Procedure InitHook(); 
var 
    dwThreadID : DWORD; 
begin 
    dwThreadID := GetCurrentThreadId; 
    hhk := SetWindowsHookEx(WH_CBT, @CBT_FUNC, hInstance, dwThreadID); 
    if hhk=0 then RaiseLastOSError; 
end; 


Procedure KillHook(); 
begin 
    if (hhk <> 0) then 
    UnhookWindowsHookEx(hhk); 
end; 


initialization 
    InitHook(); 

finalization 
    KillHook(); 
end. 

Answer 3

Ecco un codice "pseudo" si potrebbe provare (non testato):

const 
    MY_PRINT_PREVIEW_MSG = WM_USER + 200; 

type 
    TForm1 = class(TForm) 
    procedure MyPrintPreviewMsg(var Msg: TMessage); message MY_PRINT_PREVIEW_MSG; 
    procedure MyPrintPreview; 
    end; 
... 
procedure TForm1.MyPrintPreviewMsg(var Msg: TMessage); 
var 
    h: HWND; 
begin 
    h := Screen.Forms[0].Handle; // if the modal dialog is VCL dialog (verify it with spy++) 
    // h := FindWindow(<class name>, <caption>); // non VCL window 
    if (h <> 0) then 
    begin 
    SetWindowText(h, 'new caption'); 
    end; 
end; 

procedure TForm1.MyPrintPreview; 
begin 
    PostMessage(Handle, MY_PRINT_PREVIEW_MSG, 0, 0); 
    ThirdPartyPrintPreview; 
end; 

Answer 4

Provare a utilizzare l'evento TScreen.OnActiveFormChange, utilizzando la proprietà TScreen.ActiveCustomForm o TScreen.ActiveForm per sapere quale TForm ha il focus:

procedure TMainForm.DoSomething; 
begin 
    Screen.OnActiveFormChange := ActiveFormChanged; 
    try 
    // do something that triggers the modal form ... 
    finally 
    Screen.OnActiveFormChange := nil; 
    end; 
end; 

procedure TMainForm.ActiveFormChanged(Sender: TObject); 
var 
    Form: TCustomForm; 
begin 
    Form := Screen.ActiveCustomForm; 
    if (Form <> nil) and (Form.ClassName = 'TModalFormClassName') then 
    Form.Caption := 'My caption'; 
end;