In Perl, qual è il modo giusto per una sottoclasse di aliasare un metodo nella classe base?

Question

Odio semplicemente come l'accessor CGI::Application per l'oggetto CGI si chiami query.

Vorrei mie classi di istanza per essere in grado di utilizzare una funzione di accesso di nome cgi per ottenere l'oggetto CGI associato con l'istanza corrente della mia CGI::Application sottoclasse.

Ecco un esempio autonomo di quello che sto facendo:

package My::Hello; 

sub hello { 
    my $self =shift; 
    print "Hello @_\n"; 
} 

package My::Merhaba; 

use base 'My::Hello'; 

sub merhaba { 
    goto sub { shift->hello(@_) }; 
} 

package main; 

My::Merhaba->merhaba('StackOverflow'); 

Questo funziona come penso che dovrebbe e non riesco a vedere alcun problema (ad esempio, se avessi voluto ereditare da My::Merhaba: sottoclassi non c'è bisogno di sapere nulla di merhaba).

Sarebbe stato meglio/più corretto scrivere

sub merhaba { 
    my $self = shift; 
    return $self->hello(@_); 
} 

Quali sono i vantaggi/svantaggi di usare goto &NAME allo scopo di aliasing un nome di metodo? C'è un modo migliore?

Nota: Se avete una voglia di rispondere con goto è il male non lo fanno perché questo uso di goto di Perl è diverso da quello che avete in mente.

Answer 1

Il tuo approccio con goto è quello giusto, perché assicurerà che caller/wantarray e simili continuino a funzionare correttamente.

avrei messa a punto del nuovo metodo come questo:

sub merhaba { 
    if (my $method = eval {$_[0]->can('hello')}) { 
     goto &$method 
    } else { 
     # error code here 
    } 
} 

Oppure, se non si desidera utilizzare l'ereditarietà, è possibile aggiungere il nuovo metodo per il pacchetto esistente dal codice chiamante:

*My::Hello::merhaba = \&My::Hello::hello; 
    # or you can use = My::Hello->can('hello'); 

quindi è possibile chiamare:

My::Hello->merhaba('StackOverflow'); 

e ottenere il risultato desiderato.

In entrambi i casi, la route di ereditarietà è più gestibile, ma l'aggiunta del metodo al pacchetto esistente comporterebbe chiamate di metodo più veloci.

Edit:

Come sottolineato nei commenti, ci sono alcuni casi sono stati l'assegnazione glob verrà eseguito afoul con l'ereditarietà, quindi in caso di dubbio, usa il primo metodo (la creazione di un nuovo metodo in un pacchetto sub).

Michael Carman ha suggerito che unisce entrambe le tecniche in una funzione di auto ridefinizione:

sub merhaba { 
    if (my $method = eval { $_[0]->can('hello') }) { 
     no warnings 'redefine'; 
     *merhaba = $method; 
     goto &merhaba; 
    } 
    die "Can't make 'merhaba' an alias for 'hello'"; 
} 

Answer 2

È possibile alias i sottoprogrammi manipolando la tabella dei simboli:

*My::Merhaba::merhaba = \&My::Hello::hello; 

Alcuni esempi possono essere trovati here.

Answer 3

Non sono sicuro di ciò che il modo giusto è, ma Adam Kennedy usa il secondo metodo (cioè senza goto) in Method::Alias (click here to go directly to the source code).

Answer 4

Questa è una sorta di combinazione di Quick-n-Dirty con un minimo di riferimento indiretto utilizzando UNIVERSAL::can.

package My::Merhaba; 
use base 'My::Hello'; 
# ... 
*merhaba = __PACKAGE__->can('hello'); 

e avrete un sub chiamato "merhaba" in questo pacchetto che alias My::Hello::hello. Stai semplicemente dicendo che qualunque cosa questo pacchetto farebbe altrimenti sotto il nome hello che può fare sotto il nome merhaba.

Tuttavia, questo è insufficiente nella possibilità che alcuni decoratori di codice possano modificare il sottotitolo a cui punta *My::Hello::hello{CODE}. In tal caso, Method::Alias potrebbe essere il modo appropriato per specificare un metodo, come suggerito dalle molecole.

Tuttavia, se si tratta di una libreria piuttosto ben controllata in cui si controllano entrambe le categorie padre e figlio, il metodo sopra riportato è slimmmer.