VB.NET Comportamento delle parole chiave WithEvents: restrizione del compilatore VB.NET?

Question

Sto lavorando per diventare familiare con C# come lo sono con VB.NET (il linguaggio utilizzato sul mio posto di lavoro). Una delle cose migliori del processo di apprendimento è che imparando l'altra lingua si tende ad imparare di più sulla propria lingua primaria: piccole domande come questa:

Secondo le fonti che ho trovato e passato esperienza, un campo in VB.NET dichiarato come WithEvents è in grado di generare eventi. Capisco che C# non ha un equivalente diretto - ma la mia domanda è: campi senza questa parola chiave in VB.NET non può generare eventi, c'è un modo per creare questo stesso comportamento in C#? Il compilatore VB semplicemente blocca questi oggetti dall'avere gestito i loro eventi (mentre in realtà consente loro di aumentare gli eventi come al solito)?

Sono solo curioso; Non ho alcuna domanda particolare per la domanda ...

Answer 1

Omettere WithEvents non impedisce ai membri di generare eventi. Ti impedisce semplicemente di utilizzare la parola chiave "maniglie" sui loro eventi.

Ecco un uso normale WithEvents:

Class C1 
    Public WithEvents ev As New EventThrower() 
    Public Sub catcher() Handles ev.event 
     Debug.print("Event") 
    End Sub 
End Class 

Ecco una classe che non utilizza WithEvents ed è approssimativamente equivalente. Esso dimostra perché WithEvents è molto utile:

Class C2 
    Private _ev As EventThrower 
    Public Property ev() As EventThrower 

     Get 
      Return _ev 
     End Get 

     Set(ByVal value As EventThrower) 
      If _ev IsNot Nothing Then 
        removehandler _ev.event, addressof catcher 
      End If 
      _ev = value 
      If _ev IsNot Nothing Then 
        addhandler _ev.event, addressof catcher 
      End If 
     End Set 
    End Property 

    Public Sub New() 
     ev = New EventThrower() 
    End Sub 

    Public Sub catcher() 
     Debug.print("Event") 
    End Sub 
End Class