L'evidenziazione della sintassi non è attivata in vim quando si aprono più file usando argdo

Question

Apri spesso interi set di file contemporaneamente da MacVim. Per fare questo, io di solito uso i comandi:

args *PATTERN* 
argdo tabedit 

Questo carica tutti i file nella directory di lavoro che corrispondono al modello nella lista degli argomenti, e poi li si apre in schede separate. L'evidenziazione della sintassi non viene attivata automaticamente quando lo faccio e devo impostarlo manualmente. Come posso risolvere questo?

Answer 1

Avevo già posted a workaround per :bufdo in una domanda simile; ecco una versione estesa che gestisce anche il tuo caso d'uso. Lavorando intorno l'impostazione automatica di 'eventignore' è abbastanza complicato, quindi è ampiamente commentato:

" Enable syntax highlighting when buffers are displayed in a window through 
" :argdo and :bufdo, which disable the Syntax autocmd event to speed up 
" processing. 
augroup EnableSyntaxHighlighting 
    " Filetype processing does happen, so we can detect a buffer initially 
    " loaded during :argdo/:bufdo through a set filetype, but missing 
    " b:current_syntax. Also don't do this when the user explicitly turned off 
    " syntax highlighting via :syntax off. 
    " The following autocmd is triggered twice: 
    " 1. During the :...do iteration, where it is inactive, because 
    " 'eventignore' includes "Syntax". This speeds up the iteration itself. 
    " 2. After the iteration, when the user re-enters a buffer/window that was 
    " loaded during the iteration. Here is becomes active and enables syntax 
    " highlighting. Since that is done buffer after buffer, the delay doesn't 
    " matter so much. 
    " Note: When the :...do command itself edits the window (e.g. :argdo 
    " tabedit), the BufWinEnter event won't fire and enable the syntax when the 
    " window is re-visited. We need to hook into WinEnter, too. Note that for 
    " :argdo split, each window only gets syntax highlighting as it is entered. 
    " Alternatively, we could directly activate the normally effectless :syntax 
    " enable through :set eventignore-=Syntax, but that would also cause the 
    " slowdown during the iteration Vim wants to avoid. 
    " Note: Must allow nesting of autocmds so that the :syntax enable triggers 
    " the ColorScheme event. Otherwise, some highlighting groups may not be 
    " restored properly. 
    autocmd! BufWinEnter,WinEnter * nested if exists('syntax_on') && ! exists('b:current_syntax') && ! empty(&l:filetype) && index(split(&eventignore, ','), 'Syntax') == -1 | syntax enable | endif 

    " The above does not handle reloading via :bufdo edit!, because the 
    " b:current_syntax variable is not cleared by that. During the :bufdo, 
    " 'eventignore' contains "Syntax", so this can be used to detect this 
    " situation when the file is re-read into the buffer. Due to the 
    " 'eventignore', an immediate :syntax enable is ignored, but by clearing 
    " b:current_syntax, the above handler will do this when the reloaded buffer 
    " is displayed in a window again. 
    autocmd! BufRead * if exists('syntax_on') && exists('b:current_syntax') && ! empty(&l:filetype) && index(split(&eventignore, ','), 'Syntax') != -1 | unlet! b:current_syntax | endif 
augroup END 

Answer 2

io non sono a conoscenza args o argdo ma se avete bisogno di aprire i file che corrispondono a un modello in diverse schede è possibile usare qualcosa come:

:next * 
:tab ball 

:next * apre tutti i file maching il modello con la corretta evidenziazione della sintassi tuttavia, :tab ball apre tutti i file in memoria, il che potrebbe essere un problema se si dispone di buffer che non è necessario aprire nelle schede.

Answer 3

argdo aggiunge Syntax all'impostazione 'eventignore' (vedere :h argdo). Ciò significa che non hai alcun evidenziamento per quei file perché l'evento autocommand della sintassi non viene attivato per quel buffer. Il che fa sembrare che lo 'filetype' non sia impostato. Questo non è vero. È possibile verificare facendo un :set ft?. È possibile eseguire :syntax on per tornare all'evidenziazione della sintassi. Ma questo non è davvero desiderabile e si sente kludgy.

Probabilmente un approccio migliore è quello di liberarsi dall'uso delle schede e utilizzare invece i buffer ei relativi comandi del buffer. I comandi buffer relativi a Arglist sono: :next, :previous, :first e :last. È possibile aprire file specifici con :b file.c o :sb file.c per aprire il buffer in una nuova divisione.

Mi rendo conto che questa è una pillola difficile da inghiottire e ci sono certamente volte in cui si può davvero volere ogni buffer nella propria scheda. Una volta che ti imponi di usare i buffer di più, scoprirai che la necessità di schede è rara. Si consiglia di guardare l'eccellente Vimcast di Drew Neil su How to use tabs. Raccomando anche di utilizzare Tim Pope unimpaired.vim per spostarsi più facilmente nella lista degli argomenti.

Se davvero necessario disporre di ciascuno nel file in uso proprio scheda :argdo tabe allora probabilmente si dovrebbe seguire con un :syntax on o :tabdo doautocmd Syntax

Per maggiori spiegazioni, vedi:

:h :argdo 
:h arglist 
:h buffers 
:h :b 
:h :sb 
:h :next 
:h :tabdo 
:h :doa 
:h Syntax 
:h :syn-on 

Answer 4

Qualcosa del genere dovrebbe funzionare :

:argdo set eventignore-=Syntax | tabedit 

che rimuove Syntax dall'impostazione eventignore.