attributo letterale non funziona

Question

Dopo aver letto la risposta di Chris' per F# - public literal e il post sul blog a http://blogs.msdn.com/b/chrsmith/archive/2008/10/03/f-zen-the-literal-attribute.aspx Non capisco il motivo per cui il seguente non funziona:

[<Literal>] 
let one = 1 

[<Literal>] 
let two = 2 

let trymatch x = 
    match x with 
    | one -> printfn "%A" one 
    | two -> printfn "%A" two 
    | _ -> printfn "none" 


trymatch 3 

Ciò mantiene la stampa '3', anche se penso che non dovrebbe. Che cosa non vedo qui?

Answer 1

Penso che i letterali debbano essere maiuscoli. Le seguenti opere di bene:

[<Literal>] 
let One = 1 
[<Literal>] 
let Two = 2 

let trymatch x = 
    match x with 
    | One -> printfn "%A" One 
    | Two -> printfn "%A" Two 
    | _ -> printfn "none" 


trymatch 3 

Inoltre, se si desidera una soluzione generale bello per questo senza usare letterali, è possibile definire un modello attivo con parametri in questo modo:

let (|Equals|_|) expected actual = 
    if actual = expected then Some() else None 

E poi basta scrivere

let one = 1 
let two = 2 

let trymatch x = 
    match x with 
    | Equals one -> printfn "%A" one 
    | Equals two -> printfn "%A" two 
    | _ -> printfn "none" 

Answer 2

non chiedetemi perché, ma funziona quando si scrivono i letterali maiuscolo:

[<Literal>] 
let One = 1 
[<Literal>] 
let Two = 2 

let trymatch (x:int) = 
    match x with 
    | One -> printfn "%A" One 
    | Two -> printfn "%A" Two 
    | _ -> printfn "none" 

trymatch 3 

Answer 3

Anche se non si vuole avere letterali maiuscole li si può mettere in un modulo (qui chiamato Cost):

module Const = 
    [<Literal>] 
    let one = 1 
    [<Literal>] 
    let two = 2 

let trymatch x = 
    match x with 
    | Const.one -> printfn "%A" Const.one 
    | Const.two -> printfn "%A" Const.two 
    | _ -> printfn "none" 

trymatch 3 

Answer 4

Le altre risposte sono giuste - è necessario avviare l'identificativo con una lettera maiuscola . Vedere la sezione 7.1.2 of the spec (Patterns denominati), quale:

Se a lungo ident è un identificatore unico che non inizia con un carattere maiuscolo allora è sempre interpretata come un modello variabile vincolante e rappresenta una variabile che è vincolato al modello