Esiste una funzione standard di Delphi per l'escape dell'HTML?

Question

Ho un report che dovrebbe controllare la griglia e produrre output HTML. Una delle colonne nella griglia può visualizzare uno qualsiasi di un numero di valori, oppure <Any>. Quando viene generato in HTML, ovviamente, finisce vuoto.

Probabilmente potrei scrivere alcune routine per utilizzare StringReplace per trasformarlo in <Any> in modo da visualizzare correttamente questo caso particolare, ma immagino ci sia probabilmente uno nella RTL da qualche parte che è già stato testato e funziona correttamente. Qualcuno sa dove potrei trovarlo?

Answer 1

Sono sicuro al 99% che tale funzione non esiste nella RTL (come da Delphi 2009). Naturalmente - tuttavia - è banale scrivere una tale funzione.

Aggiornamento

HTTPUtil.HTMLEscape è quello che state cercando:

function HTMLEscape(const Str: string): string; 

non oso di pubblicare il codice qui (violazione di copyright, probabilmente), ma la routine è molto semplice Codifica "<", ">", "&", e """ per <, >, & e ". Essa sostituisce anche caratteri # 92, # 160 .. # 255 in decimale codici, ad esempio \.

quest'ultimo passaggio non è necessario se il file è UTF-8, e anche illogica, perché i caratteri speciali più elevate, come ad esempio ∮ sono lasciati così come sono, mentre i caratteri speciali inferiori, come ×, sono codificati.

Aggiornamento 2

In risposta alla risposta di Stijn Sanders, ho fatto un semplice test delle prestazioni.

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    Windows, SysUtils; 

var 
    t1, t2, t3, t4: Int64; 
    i: Integer; 
    str: string; 
const 
    N = 100000; 


function HTMLEncode(const Data: string): string; 
var 
    i: Integer; 
begin 

    result := ''; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': result := result + '&lt;'; 
     '>': result := result + '&gt;'; 
     '&': result := result + '&amp;'; 
     '"': result := result + '&quot;'; 
    else 
     result := result + Data[i]; 
    end; 

end; 

function HTMLEncode2(Data: string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&amp;',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]); 
end; 

begin 

    QueryPerformanceCounter(t1); 
    for i := 0 to N - 1 do 
    str := HTMLEncode('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t2); 

    QueryPerformanceCounter(t3); 
    for i := 0 to N - 1 do 
    str := HTMLEncode2('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t4); 

    Writeln(IntToStr(t2-t1)); 
    Writeln(IntToStr(t4-t3)); 

    Readln; 


end. 

L'uscita è

532031 
801969 

Answer 2

Io di solito basta usare questo codice:

function HTMLEncode(Data:string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]), 
     #13#10,'<br />'#13#10,[rfReplaceAll]); 
end; 

(? Copyright E 'open source)

Answer 3

Sembra ecco un piccolo contest :) Ecco un'altra implementazione:

function HTMLEncode3(const Data: string): string; 
var 
    iPos, i: Integer; 

    procedure Encode(const AStr: String); 
    begin 
    Move(AStr[1], result[iPos], Length(AStr) * SizeOf(Char)); 
    Inc(iPos, Length(AStr)); 
    end; 

begin 
    SetLength(result, Length(Data) * 6); 
    iPos := 1; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': Encode('&lt;'); 
     '>': Encode('&gt;'); 
     '&': Encode('&amp;'); 
     '"': Encode('&quot;'); 
    else 
     result[iPos] := Data[i]; 
     Inc(iPos); 
    end; 
    SetLength(result, iPos - 1); 
end; 

Aggiornamento 1: aggiornato inizialmente fornito codice errato.

Update 2: E i tempi:

HTMLEncode : 2286508597 
HTMLEncode2: 3577001647 
HTMLEncode3: 361039770 

Answer 4

Unità HTTPApp ha una funzione chiamata HTMLEncode. Ha anche altre funzioni correlate HTML/HTTP.

Answer 5

come su quel modo di caratteri speciali sostitutivi:

function HtmlWeg(sS: String): String; 
var 
    ix,cc: Integer; 
    sC, sR: String; 
begin 
    result := sS; 
    ix := pos('\u00',sS); 

    while ix >0 do 
    begin 
    sc := copy(sS,ix+4,2) ; 
    cc := StrtoIntdef('$' +sC,32); 
    sR := '' + chr(cc); 
    sS := Stringreplace(sS, '\u00'+sC,sR,[rfreplaceall]) ; 
    ix := pos('\u00',sS); 
    end; 
    result := sS; 
end; 

Answer 6

mia funzione combina il ciclo for con una riallocazione minima della stringa:

function HtmlEncode(const Value: string): string; 
var 
    i: Integer; 

begin 
    Result := Value; 
    i := 1; 

    while i <= Length(Result) do 
    begin 
    if Result[i] = '<' then 
    begin 
     Result[i] := '&'; 
     Insert('lt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '>' then 
    begin 
     Result[i] := '&'; 
     Insert('gt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '"' then 
    begin 
     Result[i] := '&'; 
     Insert('quot;', Result, i + 1); 
     Inc(i, 6); 
    end 
    else if Result[i] = '&' then 
    begin 
     Insert('amp;', Result, i + 1); 
     Inc(i, 5); 
    end 
    else 
     Inc(i); 
    end; 
end; 

Answer 7

Non so in cui Delphi versione è ma è stato introdotto, c'è l'unità System.NetEncoding che ha:

TNetEncoding.HTML.Encode 
TNetEncoding.HTML.Decode 

f unzioni. Leggi here. Non hai più bisogno di librerie esterne per questo.