Come attivare una macro dopo la ricezione di una nuova posta in Outlook?

Question

Sto scrivendo una macro che crea ticket su un database in base agli avvisi ricevuti da un server Nagios come e-mail. Tuttavia, non posso lasciare che la macro venga eseguita in un ciclo infinito mentre si controlla la posta, perché è troppo pesante per le risorse e causa il blocco del desktop. Devo trovare un modo per attivare la macro solo quando viene ricevuta una nuova mail.

Ho cercato qualcosa sulla falsariga degli eventi NewMail sul sito Web MSDN, ma non riesco a trovare nulla di coerente. Qualcuno può mostrarmi solo un po 'di codice di esempio per mostrare come attivare macro da nuovi eventi di posta?

Answer 1

Questo codice aggiungerà un listener di eventi alla Posta in arrivo locale predefinita, quindi eseguirà un'azione sulle e-mail in arrivo. Devi aggiungere quell'azione nel codice qui sotto.

Private WithEvents Items As Outlook.Items 
Private Sub Application_Startup() 
    Dim olApp As Outlook.Application 
    Dim objNS As Outlook.NameSpace 
    Set olApp = Outlook.Application 
    Set objNS = olApp.GetNamespace("MAPI") 
    ' default local Inbox 
    Set Items = objNS.GetDefaultFolder(olFolderInbox).Items 
End Sub 
Private Sub Items_ItemAdd(ByVal item As Object) 

    On Error Goto ErrorHandler 
    Dim Msg As Outlook.MailItem 
    If TypeName(item) = "MailItem" Then 
    Set Msg = item 
    ' ****************** 
    ' do something here 
    ' ****************** 
    End If 
ProgramExit: 
    Exit Sub 
ErrorHandler: 
    MsgBox Err.Number & " - " & Err.Description 
    Resume ProgramExit 
End Sub 

Dopo incollare il codice nel modulo ThisOutlookSession, è necessario riavviare Outlook.

Answer 2

provare qualcosa di simile all'interno ThisOutlookSession:

Private Sub Application_NewMail() 
    Call Your_main_macro 
End Sub 

mio outlook VBA appena sparato quando ho ricevuto una e-mail e aveva quell'evento applicazione aperta.

Modifica: ho appena testato un messaggio di Hello world msg e è stato eseguito dopo essere stato chiamato nell'evento application_newmail quando è stata ricevuta un'email.