Come disabilitare lo schermo in Commodore 64?

Question

So che questa domanda è molto spesifica, ma so che ci sono alcuni guru del codice C64 da queste parti. Quindi questa è la mia domanda.

Quando provo a disabilitare lo schermo utilizzando il trucco $ d011, si apre anche il bordo superiore/inferiore. Voglio farlo senza aprire i bordi superiore/inferiore. È possibile?

Answer 1

Oh, una domanda c64. Bello. :) Ho un campione nel mio archivio di codice. Devi fare il trucco $ d011 all'inizio dello schermo, non alla fine.

Questo è un codice sorgente ACME.

!to "nobadlines.prg",cbm 

!macro WAIT .v { 
    ldy #.v 
    dey 
    bne *-1 
} 

    * = $0801 
    !byte $0c, $08, $00, $00, $9e, $32, $30, $36, $31, $00, $00, $00 

    * = $080d 
    lda #$01 
    sta $3fff 
    sei 
start: 
    lda #$30 
    cmp $d012 
    bne *-3 
    lda #$00 
    sta $d011 
    +WAIT 24 
    lda #$0b 
    sta $d011 
    lda #$31 
    cmp $d012 
    bne *-3 
    lda #$1b 
    sta $d011 
    +WAIT 8 
    bit $ea 
    ldx #$00 
loop1: 
    txa 
    sta $d020 
    sta $d021 
    +WAIT 9 
    inx 
    cpx #254 
    bne loop1 
    asl $3fff 
    bne start 
    inc $3fff 
    jmp start