In Perl, come posso scorrere su più elementi di un array?

Question

Ho un file CSV che uso split per analizzare una serie di articoli N, dove N è un multiplo di 3.

C'è un modo posso fare questo

foreach my ($a, $b, $c) (@d) {} 

simile a Python?

Answer 1

è possibile utilizzare List::MoreUtils::natatime Dalla documentazione:.

my @x = ('a' .. 'g'); 
my $it = natatime 3, @x; 
while (my @vals = $it->()) { 
    print "@vals\n"; 
} 

natatime è implementato in XS così si dovrebbe preferire per l'efficienza solo a scopo illustrativo, ecco come si potrebbe implementare un tre. elemento generatore di iteratore in Perl:

#!/usr/bin/perl 

use strict; use warnings; 

my @v = ('a' .. 'z'); 

my $it = make_3it(\@v); 

while (my @tuple = $it->()) { 
    print "@tuple\n"; 
} 

sub make_3it { 
    my ($arr) = @_; 
    { 
     my $lower = 0; 
     return sub { 
      return unless $lower < @$arr; 
      my $upper = $lower + 2; 
      @$arr > $upper or $upper = $#$arr; 
      my @ret = @$arr[$lower .. $upper]; 
      $lower = $upper + 1; 
      return @ret; 
     } 
    } 
} 

Answer 2

@z=(1,2,3,4,5,6,7,8,9,0); 

for(@tuple=splice(@z,0,3); @tuple; @tuple=splice(@z,0,3)) 
{ 
    print "$tuple[0] $tuple[1] $tuple[2]\n"; 
} 

produce:

1 2 3 
4 5 6 
7 8 9 
0 

Answer 3

Non

facilmente. Si sarebbe meglio fare @d una serie di tuple di tre elementi, spingendo gli elementi sulla matrice come un riferimento ad array:

foreach my $line (<>) 
    push @d, [ split /,/, $line ]; 

(tranne che si dovrebbe davvero utilizzare uno dei moduli CSV da CPAN .

Answer 4

ho affrontato la questione nel mio modulo List::Gen su CPAN.

use List::Gen qw/by/; 

for my $items (by 3 => @list) { 

    # do something with @$items which will contain 3 element slices of @list 

    # unlike natatime or other common solutions, the elements in @$items are 
    # aliased to @list, just like in a normal foreach loop 

} 

Si potrebbe anche importare la funzione mapn, che viene utilizzato da List::Gen per implementare by:

use List::Gen qw/mapn/; 

mapn { 

    # do something with the slices in @_ 

} 3 => @list; 

Answer 5

my @list = (qw(one two three four five six seven eight nine)); 

while (my ($m, $n, $o) = splice (@list,0,3)) { 
    print "$m $n $o\n"; 
} 

queste uscite:

one two three 
four five six 
seven eight nine