C'è un modo per visualizzare i tempi di compilazione di un'intera soluzione in Visual Studio?

Question

So che c'è a way to display the build time of each project contained in a solution in visual studio. Ma quello che sto cercando è il tempo totale necessario per costruire un'intera soluzione, dal momento in cui ho fatto clic su build, fino al momento in cui è stata eseguita.

Esiste comunque? Esecuzione di Visual Studio 2008.

Answer 1

EDIT: Ecco un modo è possibile scrivere il tempo di costruzione direttamente alla finestra di compilazione.

Apre l'IDE di Visual Studio Macro.
Passare a MyMacros> EnvironmentEvents.
In MyMacros, aggiungere un riferimento a System.Windows.Forms (per il codice seguente per visualizzare una finestra popup).
Aggiungere questo codice al modulo EnvironmentEvents:

Dim buildStart As Date 

Private Function IsBuild(ByVal scope As EnvDTE.vsBuildScope, ByVal action As EnvDTE.vsBuildAction) As Boolean 
    Return scope = vsBuildScope.vsBuildScopeSolution AndAlso (action = vsBuildAction.vsBuildActionBuild OrElse action = vsBuildAction.vsBuildActionRebuildAll) 
End Function 

Private Sub BuildEvents_OnBuildBegin(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildBegin 
    If (IsBuild(Scope, Action)) Then 
     buildStart = Date.Now 
    End If 
End Sub 

Private Sub BuildEvents_OnBuildDone(ByVal Scope As EnvDTE.vsBuildScope, ByVal Action As EnvDTE.vsBuildAction) Handles BuildEvents.OnBuildDone 
    If (IsBuild(Scope, Action)) Then 
     Dim buildTime = Date.Now - buildStart 
     WriteToBuildWindow(String.Format("Build time: {0}", buildTime.ToString)) 
    End If 
End Sub 

Private Sub WriteToBuildWindow(ByVal message As String) 
    Dim win As Window = DTE.Windows.Item(EnvDTE.Constants.vsWindowKindOutput) 
    Dim ow As OutputWindow = CType(win.Object, OutputWindow) 
    For Each owPane As OutputWindowPane In ow.OutputWindowPanes 
     If (owPane.Name.Equals("Build")) Then 
      owPane.OutputString(message) 
      Exit For 
     End If 
    Next 
End Sub 

Quando costruire o ricostruire la soluzione completa, alla fine, la costruzione/ricostruzione durata verrà stampato nella finestra di output di generazione. È possibile modificare le condizioni in IsBuild in base alle proprie preferenze.

Answer 2

Strumenti> Opzioni> Progetti e Solutions-> VC++ Progetto Impostazioni-> Crea Timing