Clojure costruzione di URL da parti costituenti

Question

In Python vorrei fare le seguenti operazioni:

>>> q = urllib.urlencode({"q": "clojure url"}) 
>>> q 
'q=clojure+url' 

>>> url = "http://stackoverflow.com/search?" + q 
>>> url 
'http://stackoverflow.com/search?q=clojure+url' 

Come faccio a fare tutto la codifica che ha fatto per me in precedenza in Clojure? In altre parole, come faccio a fare qualcosa di simile a quanto segue:

=> (build-url "http://stackoverflow.com/search" {"q" "clojure url"}) 
"http://stackoverflow.com/search?q=clojure+url" 

Answer 1

Ecco un modo:

user=> (import [java.net URLEncoder])              
java.net.URLEncoder 
user=> (str "http://stackoverflow.com/search?q=" (URLEncoder/encode "clojure url" "UTF-8")) 
"http://stackoverflow.com/search?q=clojure+url" 

lo so questo non è esattamente lo stesso del tuo frammento Python. Si prega di consultare il seguente post dalla mailing list Clojure per una risposta più completa:

http://www.mail-archive.com/clojure@googlegroups.com/msg29338.html

Il codice da lì vi permetterà di fare questo:

user=> (encode-params {"q" "clojure url"}) 
"q=clojure+url" 

Answer 2

Una soluzione semplice usando str (Ings):

(def q (str "clojure+url")) 
(def url (str "http://stackoverflow.com/search?" q)) 

Answer 3

c'è una funzione url-encode in Ring ring.util.codec namespace:

(ring.util.codec/url-encode "clojure url") 
; => "clojure+url" 

non sono sicuro se c'è una funzione preconfezionato per trasformare una mappa in una quer y stringa, ma forse questo potrebbe fare il lavoro:

(use '[ring.util.codec :only [url-encode]]) 

(defn make-query-string [m] 
    (->> (for [[k v] m] 
     (str (url-encode k) "=" (url-encode v))) 
     (interpose "&") 
     (apply str))) 

Un esempio:

user> (make-query-string {"q" "clojure url" "foo" "bar"}) 
"q=clojure+url&foo=bar" 

non rimane che concatenando il risultato sull'estremità di un URL:

(defn build-url [url-base query-map] 
    (str url-base "?" (make-query-string query-map))) 

Sembra al lavoro:

user> (build-url "http://stackoverflow.com/search" {"q" "clojure url"}) 
"http://stackoverflow.com/search?q=clojure+url" 

---

Aggiornamento:

Forse una versione modificata potrebbe fare per un'esperienza più Clojure-friendly. Gestisce anche la codifica tramite un argomento opzionale in stile Ring con utf-8 come predefinito.

(defn make-query-string [m & [encoding]] 
    (let [s #(if (instance? clojure.lang.Named %) (name %) %) 
     enc (or encoding "UTF-8")] 
    (->> (for [[k v] m] 
      (str (url-encode (s k) enc) 
       "=" 
       (url-encode (str v) enc))) 
     (interpose "&") 
     (apply str)))) 

(defn build-url [url-base query-map & [encoding]] 
    (str url-base "?" (make-query-string query-map encoding))) 

Così ora possiamo fare

user> (build-url "http://example.com/q" {:foo 1}) 
"http://example.com/q?foo=1" 

Answer 4

clj-apache-http è molto utile. Con esso è possibile effettuare le seguenti operazioni:

user=> (require ['com.twinql.clojure.http :as 'http]) 
nil 
user=> (def q (http/encode-query {"q" "clojure url"})) 
#'user/q 
user=> (def url (str "http://stackoverflow.com/search?" q)) 
#'user/url 
user=> url 
"http://stackoverflow.com/search?q=clojure+url" 

Answer 5

Questo è l'esatto equivalente REPL della sessione di pitone, con clj-http.

user=> (require ['clj-http.client :as 'client]) 
nil 
user=> (str "http://stackoverflow.com/search?" 
user=*  (client/generate-query-string {"q" "clojure url"})) 
"http://stackoverflow.com/search?q=clojure+url" 

ma CLJ-http rende ancora più facile:

user=> (client/get "http://stackoverflow.com/search?" 
user=*    {:query-params {"q" "clojure url"}}) 
... <a lot of output, omitted to protect the innocent>... 

supponendo che si desidera eseguire una richiesta GET, che è.