Delphi 'in' sovraccarico operatore su un set

Question

In Delphi XE2, sto cercando di sovraccaricare l'operatore in su un record per consentirmi di verificare se il valore rappresentato dal record fa parte di un set. Il mio codice è simile al seguente:

type 
    MyEnum = (value1, value2, value3); 
    MySet = set of MyEnum; 
    MyRecord = record 
    Value: MyEnum; 
    class operator In(const A: MyRecord; B: MySet): Boolean; 
    end; 

class operator MyRecord.In(const A: MyRecord; B: MySet): Boolean; 
begin 
    Result := A.Value in B; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    R: MyRecord; 
    S: MySet; 
begin 
    R.Value := value1; 
    S := [value1, value2]; 
    Button1.Caption := BoolToStr(R in S); 
end; 

Il codice non viene compilato. Per la dichiarazione R in S il compilatore dice: tipi incompatibili MyRecord e MyEnum.

Come posso sovraccaricare l'operatore In su MyRecord in modo che R in S valuterà al True nel codice di cui sopra?

Answer 1

Beh, quasi si può fare questo, ma non si può decidere a. AFAIK, gli operatori di classe lavorano solo sulla classe (o sulla registrazione) in cui sono definiti all'interno, quindi sia R che S nel codice devono essere TMyRecord. Con un po 'l'uso sconsiderato di fusione implicita, otteniamo la seguente:

unit Unit2; 
interface 
type 
    MyEnum = (value1, value2, value3); 
    MySet = set of MyEnum; 
    MyRecord = record 
    Value: MyEnum; 
    ValueSet: MySet; 
    class operator Implicit(A: MyEnum): MyRecord; 
    class operator Implicit(A: MySet): MyRecord; 
    class operator In (Left,Right:MyRecord): Boolean; 
    end; 

implementation 

class operator MyRecord.Implicit(A: MyEnum): MyRecord; 
begin 
    Result.Value := A; 
end; 

class operator MyRecord.Implicit(A: MySet): MyRecord; 
begin 
    Result.ValueSet := A; 
end; 

class operator MyRecord.In(Left, Right: MyRecord): Boolean; 
begin 
    Result:= left.Value in Right.ValueSet; 
end; 
end. 

Di seguito sarà ora complile, e anche il lavoro:

procedure TForm1.Button1Click(Sender: TObject); 
var 
    R: MyRecord; 
    S: MyRecord; 
begin 
    R.Value := value1; 
    S := [value1,value2,value3]; 
    Button1.Caption := BoolToStr(R In S,true); 
end; 

Il che, sono sicuro che saremo tutti d'accordo, è molto più elegante di 'BoolToStr (R.Value in S)'. Tuttavia la seguente sarà anche compilare, ma indica il risultato sbagliato:

procedure TForm1.Button1Click(Sender: TObject); 
var 
    R: MyRecord; 
    S: MyRecord; 
begin 
    R.Value := value1; 
    S := [value1,value2,value3]; 
    Button1.Caption := BoolToStr(S In R,true); 
end; 

Così, come ha commentato Dorin, meglio semplicemente noioso, posata vecchio 'BoolToStr (R.Value in S)'. A meno che non venga pagato per riga di codice. E un bonus per la risoluzione dei bug.

Answer 2

Per l'operatore in a, l'operando di destra deve essere del tipo di record poiché è un operatore impostato e non un operatore binario. Nel tuo caso è l'operando di sinistra.

Così il seguente funzionerà:

type 
    MyRecord = record 
    Value: MyEnum; 
    class operator In(const A: MyRecord; const B: MySet): Boolean; 
    end; 

    MyRecord2 = record 
    Value: MySet; 
    class operator In(const A: MyRecord; const B: MyRecord2): Boolean; 
    class operator In(const A: MyEnum; const B: MyRecord2): Boolean; 
    end; 

class operator MyRecord.In(const A: MyRecord; const B: MySet): Boolean; 
begin 
    Result := A.Value in B; 
end; 

class operator MyRecord2.In(const A: MyRecord; const B: MyRecord2): Boolean; 
begin 
    Result := A.Value in B.Value; 
end; 

class operator MyRecord2.In(const A: MyEnum; const B: MyRecord2): Boolean; 
begin 
    Result := A in B.Value; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    R: MyRecord; 
    R2: MyRecord2; 
begin 
    R.Value := value1; 
    R2.Value := [value1, value2]; 

    if R in R2 then; 
    if value1 in R2 then; 
end;