Come ordinare l'hash perl sui valori e ordinare le chiavi in ​​modo corrispondente (in due matrici)?

Question

In Perl, voglio ordinare le chiavi di un hash per valore, numerico:

{ 
    five => 5 
    ten => 10 
    one => 1 
    four => 4 
} 

producendo due matrici:

(1,4,5,10) and (one, four, five, ten) 

E poi voglio normalizzare la matrice valori tali che i numeri sono sequenziali:

(1,2,3,4) 

Come si fa?

Answer 1

Prima ordinare le chiavi con il valore associato. Quindi ottieni i valori (ad esempio usando una slice hash).

my @keys = sort { $h{$a} <=> $h{$b} } keys(%h); 
my @vals = @h{@keys}; 

Oppure se si dispone di un riferimento hash.

my @keys = sort { $h->{$a} <=> $h->{$b} } keys(%$h); 
my @vals = @{$h}{@keys}; 

Answer 2

my (@nums, @words); 
do { push @nums, shift @$_; 
    push @words, shift @$_; 
    } 
    foreach sort { $a->[0] <=> $b->[0] } 
      map { [ $h->{ $_ }, $_ ] } keys %$h 
    ; 

Answer 3

prega di consultare la voce di Perl FAQ dal titolo "Come si ordina un hash (opzionalmente per valore invece che per chiave)"

http://perldoc.perl.org/perlfaq4.html#How-do-I-sort-a-hash-%28optionally-by-value-instead-of-key%29?

È inoltre possibile utilizzare perldoc -q per cercare il Domande frequenti sul tuo computer, come in perldoc -q sort, che è il modo in cui ho trovato la tua risposta.

Answer 4

Come si ordina un hash (facoltativamente in base al valore anziché al tasto)?

Per ordinare un hash, iniziare con i tasti. In questo esempio, forniamo l'elenco delle chiavi alla funzione di ordinamento che quindi le confronta in modo ASCII (che potrebbe essere influenzato dalle impostazioni locali). L'elenco di output ha le chiavi in ​​ordine ASCIIbetic. Una volta che abbiamo le chiavi, possiamo esaminarle per creare un rapporto che elenca le chiavi in ​​ordine ASCIIbetico.

my @keys = sort { $a cmp $b } keys %hash; 

foreach my $key (@keys) { 
    printf "%-20s %6d\n", $key, $hash{$key}; 
} 

Tuttavia, nel blocco sort() si potrebbe ottenere di più. Invece di confrontare le chiavi, possiamo calcolare un valore con esse e usare quel valore come confronto.

Per esempio, per rendere il nostro ordine rapporto case-insensitive, usiamo lc in minuscolo le chiavi prima confrontandoli:

my @keys = sort { lc $a cmp lc $b } keys %hash; 

Nota: se il calcolo è costoso o l'hash ha molti elementi, si può vuoi guardare la Trasformata di Schwartz per mettere in cache i risultati del calcolo.

Se invece vogliamo ordinare per valore hash, usiamo il tasto hash per cercarlo. Abbiamo ancora una lista di chiavi, ma questa volta sono ordinate in base al loro valore.

my @keys = sort { $hash{$a} <=> $hash{$b} } keys %hash; 

Da lì possiamo diventare più complessi. Se i valori hash sono gli stessi, possiamo fornire un ordinamento secondario sulla chiave hash.

my @keys = sort { 
$hash{$a} <=> $hash{$b} 
or 
"\L$a" cmp "\L$b" 
} keys %hash;