scons: sovrascrivere le opzioni di compilazione per un file

Question

Domanda facile ma non conosco la risposta.

Diciamo che ho una build scons dove il mio CCFLAGS include -O1. Ho un file needsOptimization.cpp in cui preferirei sostituire lo -O1 con -O2. Come potrei farlo in scons?

---

aggiornamento: questo è quello che ho finito per fare in base alla risposta del bialix:

nel mio file SConscript:

Import('env'); 

env2 = env.Clone(); 
env2.Append(CCFLAGS=Split('-O2 --asm_listing')); 

sourceFiles = ['main.cpp','pwm3phase.cpp']; 
sourceFiles2 = ['serialencoder.cpp','uartTestObject.cpp']; 
objectFiles = []; 
objectFiles.append(env.Object(sourceFiles)); 
objectFiles.append(env2.Object(sourceFiles2)); 
    ... 

in precedenza questo file era:

Import('env'); 

sourceFiles = ['main.cpp','pwm3phase.cpp','serialencoder.cpp','uartTestObject.cpp']; 
objectFiles = env.Object(sourceFiles); 
    ... 

Answer 1

Usa il builder Object() per un controllo ben preciso sulla compilazione, un d poi passare questi oggetti al costruttore Program().

E.g. invece di:

env = Environment() 
env.Program(target='foo', source=['foo.cpp', 'bar.cpp', 'needsOptimisation.cpp']) 

è necessario utilizzare seguente:

env = Environment() 
env_o1 = env.Clone() 
env_o1.Append(CCFLAGS = '-O1') 

env_o2 = env.Clone() 
env_o2.Append(CCFLAGS = '-O2') 

# extend these lists if needed 
SRC_O1 = ['foo.cpp', 'bar.cpp'] 
SRC_O2 = ['needsOptimisation.cpp'] 

obj_o1 = [env_o1.Object(i) for i in SRC_O1] 
obj_o2 = [env_o2.Object(i) for i in SRC_O2] 

env.Program(target='foo', source=obj_o1+obj_o2) 

si può evitare la creazione di cloni separata della variabile ENV se fornite CCFLAGS = '- O2' proprio nella chiamata Object():

obj_o2 = [env.Object(i, CCFLAGS=env['CCFLAGS'] + ['-O2']) for i in SRC_O2] 

Answer 2

evitando di creare di una variabile ENV separata richiede (ref: bialix's answer) ha bisogno di qualcosa di simile.

obj_o2 = env.Object(SRC_O2, CCFLAGS=env['CCFLAGS'] + ['-O2']); 

Se solo fare questo (o nel ciclo for come bialix fa)

obj_o2 = env.Object(SRC_O2, CCFLAGS='-O2'); 

poi si perde tutte le bandiere built-in.