Come posso utilizzare Perl's XML :: LibXML per estrarre un attributo in un tag?

Question

Ho un file XML

<PARENT > 
<TAG string1="asdf" string2="asdf" > 
</TAG > 
</PARENT> 

Voglio estrarre il valore stringa2 qui .. e anche io voglio impostarlo su un nuovo valore ..

Come farlo?

Answer 1

Usa espressioni XPath

use strict;                              
use warnings;                              

use XML::LibXML;                             
use Data::Dumper;                             

my $doc = XML::LibXML->new->parse_string(q{                      
<PARENT>                               
    <TAG string1="asdf" string2="asdfd">                       
    </TAG>                              
</PARENT>                               
});                                

my $xpath = '/PARENT/TAG/@string2';                        
# getting value of attribute:                          
print Dumper $doc->findvalue($xpath);                        
my ($attr) = $doc->findnodes($xpath);                        

# setting new value:                            
$attr->setValue('dfdsa');                           
print Dumper $doc->findvalue($xpath);                        

# do following if you need to get string representation of your XML structure 
print Dumper $doc->toString(1);        

E leggere la documentazione, ovviamente :)

Answer 2

Si potrebbe utilizzare XML :: Parser per ottenere il valore come bene. Per ulteriori informazioni consultare il XML::Parser documentation:

#!/usr/local/bin/perl 
use strict; 
use warnings; 


use XML::Parser; 
use Data::Dumper; 

my $attributes = {}; 

my $start_handler = sub 
{ 
    my ($expat, $elem, %attr) = @_; 
    if ($elem eq 'TAG') 
    { 
     $attributes->{$attr{'string1'}} = 'Found'; 
    } 
}; 


my $p1 = new XML::Parser(
     Handlers => { 
      Start => $start_handler 
     } 
); 

$p1->parsefile('test.xml'); 

print Dumper($attributes); 

Answer 3

penso che si potrebbe essere meglio a cominciare XML::Simple e giocare un po 'prima:

#!/usr/bin/perl 

use strict; 
use warnings; 

use XML::Simple; 

my $xml = XMLin(\*DATA); 

print $xml->{TAG}->{string2}, "\n"; 

$xml->{TAG}->{string2} = "asdf"; 

print XMLout($xml, RootName => 'PARENT'); 

__DATA__ 
<PARENT> 
<TAG string1="asdf" string2="value of string 2"> 
</TAG> 
</PARENT> 

Answer 4

Grazie per le vostre risposte. Ho trovato un'altra risposta in "Config file processing with LibXML2" che ho trovato molto utile.