Come eseguire il codice di inizializzazione per una tavolozza?

Question

Occasionalmente sarebbe preferibile avere un codice di inizializzazione per le tavolozze (dei pulsanti). Ad esempio, potrebbe definire alcune funzioni utilizzate dai pulsanti della tavolozza.

Qual è il modo più semplice e preferibile per definire/eseguire il codice di inizializzazione per una tavolozza?

• L'inizializzazione può essere eseguito sia quando la tavolozza viene caricato o quando si preme un tasto per la prima volta (possibile problema:? cosa succede se il kernel è stato riavviato dopo la tavolozza è stato caricato)
• Il le definizioni dovrebbero essere in qualche modo localizzate (ad esempio nel loro contesto personale: fare in modo che i contesti di quaderno siano di aiuto?)
• Se possibile, preferirei una soluzione minima (ad esempio codice extra nel minor numero possibile di posizioni, file di palette autonomo con nessun file pacchetto aggiuntivo, creazione della tavolozza utilizzando gli strumenti di convenienza esistenti del menu delle tavolozze o CreatePalette, ecc.)
• (Si può presumere che il codice di inizializzazione sia veloce, ad es. Si compone di definizioni soltanto)

Answer 1

Hai ragione di essere preoccupato per la visibilità del Dynamic essere un problema. Il modo per garantire assolutamente un'espressione Dynamic da valutare indipendentemente dalla visibilità di una qualsiasi delle singole celle è utilizzare NotebookDynamicExpression. Ecco un esempio che illustra NotebookDynamicExpression di lavoro mentre un Dynamic fallisce perché è nascosto all'interno di un gruppo a celle chiuse:

cell1 = First @ MakeBoxes[ 
    TextCell["Click to open", "Title", 
     CellMargins -> 0, System`WholeCellGroupOpener -> True], 
    StandardForm]; 
cell2 = First @ MakeBoxes[ 
    ExpressionCell[DynamicWrapper["hidden cell", Print["DynamicWrapper"]]], 
    StandardForm]; 
CreatePalette[ 
    Notebook[{Cell[CellGroupData[{cell1, cell2}, Closed]]}, 
     NotebookDynamicExpression :> 
      Dynamic[Refresh[Print["NotebookDynamicExpression"], None]]]] 

Quando si valuta questo, si noti che il Dynamic in NotebookDynamicExpression viene valutata immediatamente. DynamicWrapper non viene mai valutato finché non si apre il gruppo di celle, che è possibile fare facendo clic sul testo "Fare clic per aprire".

In questo esempio, incidentalmente, si noti che ho avvolto lo NotebookDynamicExpression con Refresh. La funzione Refresh[#, None]& si assicurerà che il codice venga valutato solo una volta, quando il notebook viene aperto per la prima volta. In caso contrario, il codice obbedirebbe alle proprietà standard di Dynamic e valuterà ogniqualvolta una qualsiasi delle dipendenze cambierà.

NotebookDynamicExpression è in circolazione dalla v6, ma è stato documentato solo nella v8. Inoltre sono documentati i relativi cugini, CellDynamicExpression e FrontEndDynamicExpression.

Answer 2

Un DynamicBox con Initialization è capace della funzione di base. È possibile ridimensionare la tavolozza in modo tale che l'oggetto non sia visibile e continuerà a funzionare.

Questo è il codice per una piccola tavolozza campione. Imposta un valore per var. Il codice attivo è sfalsato con spazi bianchi.

(* Beginning of Notebook Content *) 
Notebook[{ 
Cell[BoxData[{ 
TagBox[GridBox[{ 
    { 
    ButtonBox["\<\"TSV\"\>", 
     Appearance->Automatic, 
     ButtonFunction:>None, 
     Evaluator->Automatic, 
     Method->"Preemptive"]}, 
    { 
    ButtonBox["\<\"CSV\"\>", 
     Appearance->Automatic, 
     ButtonFunction:>None, 
     Evaluator->Automatic, 
     Method->"Preemptive"]}, 
    { 
    ButtonBox["\<\"Table\"\>", 
     Appearance->Automatic, 
     ButtonFunction:>None, 
     Evaluator->Automatic, 
     Method->"Preemptive"]} 
    }, 
    GridBoxAlignment->{"Columns" -> {{Left}}}, 
    GridBoxItemSize->{"Columns" -> {{Automatic}}, "Rows" -> {{Automatic}}}], 
    "Column"], "\[IndentingNewLine]", 

DynamicBox[Null, 
    Initialization :> ($CellContext`var = "It is done, Master.") 
] 

}], NotebookDefault, 
CellMargins->{{0, 0}, {0, 0}}, 
CellBracketOptions->{"Color"->RGBColor[0.269993, 0.308507, 0.6]}, 
CellHorizontalScrolling->True, 
PageBreakAbove->True, 
PageBreakWithin->False, 
ShowAutoStyles->True, 
LineSpacing->{1.25, 0}, 
AutoItalicWords->{}, 
ScriptMinSize->9, 
ShowStringCharacters->False, 
FontFamily:>CurrentValue["PanelFontFamily"], 
FontSize:>CurrentValue["PanelFontSize"]] 
}, 
WindowSize->{55, 105}, 
WindowMargins->{{Automatic, 583}, {Automatic, 292}}, 
WindowFrame->"Palette", 
WindowElements->{}, 
WindowFrameElements->{"CloseBox", "MinimizeBox"}, 
StyleDefinitions->"Palette.nb" 
] 
(* End of Notebook Content *)