Scrivi stringa in un TFileStream in Delphi 2010

Question

ho Delphi codice 2007, che assomiglia a questo:

procedure WriteString(Stream: TFileStream; var SourceBuffer: PChar; s: string); 
begin 
    StrPCopy(SourceBuffer,s); 
    Stream.Write(SourceBuffer[0], StrLen(SourceBuffer)); 
end; 

io lo chiamo così:

var 
    SourceBuffer : PChar; 
    MyFile: TFileStream; 

.... 

SourceBuffer := StrAlloc(1024); 
MyFile := TFileStream.Create('MyFile.txt',fmCreate); 
WriteString(MyFile,SourceBuffer,'Some Text'); 
.... 

Questo ha funzionato in Delphi 2007, ma mi dà un sacco di personaggi spazzatura in Delphi 2010. So che questo è dovuto a problemi di conformità unicode, ma non sono sicuro di come affrontare il problema.

Ecco quello che ho provato finora:

• Modificare il tipo di dati di SourceBuffer (e anche il parametro atteso da WideString) per PWideChar

• Ognuno dei suggestions listed here

Cosa sto sbagliando?

Answer 1

Non è necessario un buffer separato per scrivere una stringa in un flusso. Probabilmente il modo più semplice per farlo è quello di codificare la stringa da UTF8, in questo modo:

procedure TStreamEx.writeString(const data: string); 
var 
    len: cardinal; 
    oString: UTF8String; 
begin 
    oString := UTF8String(data); 
    len := length(oString); 
    self.WriteBuffer(len, 4); 
    if len > 0 then 
     self.WriteBuffer(oString[1], len); 
end; 

function TStreamEx.readString: string; 
var 
    len: integer; 
    iString: UTF8String; 
begin 
    self.readBuffer(len, 4); 
    if len > 0 then 
    begin 
     setLength(iString, len); 
     self.ReadBuffer(iString[1], len); 
     result := string(iString); 
    end; 
end; 

ho dichiarato TStreamEx come aiutante di classe per TStream, ma non dovrebbe essere troppo difficile da riscrivere questi come procedura e funzione da solo come il tuo esempio.

Answer 2

Delphi 2010 è una bella soluzione per questo, qui documentata:

http://docwiki.embarcadero.com/CodeExamples/en/StreamStrRdWr_%28Delphi%29

var 
    Writer: TStreamWriter; 
... 

    { Create a new stream writer directly. } 
    Writer := TStreamWriter.Create('MyFile.txt', false, TEncoding.UTF8); 
    Writer.Write('Some Text'); 

    { Close and free the writer. } 
    Writer.Free();