Domanda di clojure idiomatica sulla trasformazione in sequenza

Question

Sto imparando Clojure e ho bisogno di una spinta nella giusta direzione con questo problema che mi è venuto in mente.

Ho una sequenza di eventi. Ogni evento include una "data".

(def events 
    [ 
    [1509 :marry "Catherine of Aragon"] 
    [1527 :unmarry "Catherine of Aragon"] 
    [1533 :marry "Anne Boleyn"] 
    [1536 :unmarry "Anne Boleyn"] 
    [1536 :marry "Jane Seymour"] 
    [1537 :unmarry "Jane Seymour"] 
    [1540 :marry "Anne of Cleves"] 
    [1540 :unmarry "Anne of Cleves"] 
    [1540 :marry "Catherine Howard"] 
    [1542 :unmarry "Catherine Howard"] 
    [1543 :marry "Catherine Parr"]]) 

Voglio convertire questo in una timeline pigra, cioè una sequenza contenente un vettore all'anno. A partire dall'anno del primo evento e continuando all'infinito.

[[[:marry "Catherine of Aragon"]] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [[:unmarry "Catherine of Aragon"]] [] [] [] [] [] [[:marry "Ane Boleyn"]] [] [] [[:unmarry "Anne Boleyn"] [:marry "Jayne Seymour"]] ...] 

Answer 1

(def timeline 
    (let [events-by-year (group-by first events)] 
    (map #(map next (events-by-year %)) 
     (iterate inc (reduce min (keys events-by-year)))))) 

prova rapida:

=> (take 30 timeline) 
(((:marry "Catherine of Aragon"))()()()()()()()()()()()()()()()() 
() ((:unmarry "Catherine of Aragon"))()()()()() ((:marry "Anne Boleyn"))() 
() ((:unmarry "Anne Boleyn") (:marry "Jane Seymour")) ((:unmarry "Jane Seymour")) 
()) 

Answer 2

vorrei suggerire qualcosa di simile:

(defn timeline 
    ([] (timeline (ffirst *events*) *events*)) 
    ([time evts] 
    (let [[now later] (split-with #(= time (first %)) evts)] 
     (cons (map rest now) 
      (lazy-seq (timeline (inc time) later)))))) 

prova:

user> (take 30 (timeline)) 
(((:marry "Catherine of Aragon"))()()()()()()()()()()()()()()()()() 
((:unmarry "Catherine of Aragon"))()()()()() ((:marry "Anne Boleyn"))()() 
((:unmarry "Anne Boleyn") (:marry "Jane Seymour")) ((:unmarry "Jane Seymour"))()) 

Sto assumendo che l'elenco degli eventi è infinita così :)

Aggiornato con miglioramenti e prendendo in prestito un paio di idee da cgrand (grazie :)