Come verificare se esiste un eseguibile nel% PATH% da un file batch di Windows?

Question

Sto cercando un modo semplice per verificare se esiste un eseguibile nella variabile di ambiente PATH da un file batch di Windows.

L'utilizzo di strumenti esterni non forniti dal sistema operativo non è consentito. La versione minima di Windows richiesta è Windows XP.

Answer 1

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X) 
if defined FOUND ... 

Se avete bisogno di questo per diverse estensioni, poco un'iterazione su PATHEXT:

set FOUND= 
for %%e in (%PATHEXT%) do (
    for %%X in (myExecutable%%e) do (
    if not defined FOUND (
     set FOUND=%%~$PATH:X 
    ) 
) 
) 

potrebbe essere che where esiste anche già sulle versioni precedenti di Windows, ma non hanno accesso a uno, in modo da Non posso dire. Sulla mia macchina funziona anche:

where myExecutable 

e restituisce con un codice di uscita diverso da zero se non è stato trovato. In un batch probabilmente si desidera reindirizzare l'output a NUL, tuttavia.

Answer 2

@echo off 
set found= 
set prog=cmd.exe 
for %%i in (%path%) do if exist %%i\%prog% set found=%%i 
echo "%found%" 
if "%found%"=="" .... 

Answer 3

A volte questa soluzione semplice funziona, dove si controlla se l'uscita corrisponde a ciò che si aspetta. La prima riga esegue il comando e afferra l'ultima riga dello standard output.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i 
if "%xcopyoutput%"=="" echo xcopy not in path. 

Answer 4

Questo può essere eseguito tramite la sostituzione dei parametri.

%~$PATH:1 

Restituisce il percorso completo del nome file eseguibile in% 1, altrimenti una stringa vuota.

Questo non funziona con le variabili definite dall'utente. Quindi se il nome file eseguibile non è un parametro per il tuo script, allora hai bisogno di una subroutine. Per esempio:

call :s_which app.exe 
if not "%_path% == "" (
    app.exe 
) 

goto :eof 

:s_which 
    setlocal 
    endlocal & set _path=%~$PATH:1 
    goto :eof 

Vedi http://ss64.com/nt/syntax-args.html

Answer 5

Ecco una soluzione semplice che tenta di eseguire l'applicazione e gestisce ogni errore seguito.

file.exe /? 2> NUL 
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path 

Il codice di errore 9009 indica in genere un file non trovato.

L'unico lato negativo è che file.exe viene effettivamente eseguito se trovato (che in alcuni casi non è consigliabile).

Answer 6

Windows Vista e versioni successive vengono forniti con un programma chiamato where.exe che ricerca i programmi nel percorso. Funziona in questo modo:

D:\>where notepad 
C:\Windows\System32\notepad.exe 
C:\Windows\notepad.exe 

D:\>where where 
C:\Windows\System32\where.exe 

Per l'utilizzo in un file batch è possibile utilizzare l'interruttore /q, che ha appena imposta ERRORLEVEL e non produce alcun output.

where /q myapplication 
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH. 
    EXIT /B 
) ELSE (
    ECHO Application exists. Let's go! 
) 

o una versione semplice (ma meno leggibile) stenografia che stampa il messaggio ed esce la vostra applicazione:

where /q myapplication || ECHO Cound not find app. && EXIT /B 

Answer 7

Utilizzare il comando: powershell Test-Path "exe, che si cerca di"

Restituirà True se presente, altrimenti False.