Confrontando più stringhe in Perl

Question

ho il mio codice come questo:

if ($var eq "str1" || $var eq "str2" || $var eq "str3") 
{ 
... 
} 

C'è comunque di ottimizzare questo. voglio qualcosa di simile:

if ($var eq ["str1" || "str2" || "str3"]) {...} 

Answer 1

A seconda del contenuto delle stringhe, una regex è molto conveniente:

if ($var =~ /^(str1|str2|str3)$/) { … } 

In mancanza di questo, è possibile grep su un elenco:

if (grep { $var eq $_ } qw{str1 str2 str3}) { … } 

Answer 2

In Perl 5.10 o successivo:

if ($var ~~ [qw(str1 str2 str3)]) { ...} 

L'operatore ~~ fa uno smart match tra i suoi argomenti.

Answer 3

1. Usa List::MoreUtils qw{any}

   use List::MoreUtils qw{any}; 
   
   if (any { $var eq $_ } 'str1', 'str2', 'str3') { 
       ... 
   } 
   

   Questo potrebbe essere più veloce rispetto all'utilizzo di grep perchè List::MoreUtils::any termina presto quando trova una corrispondenza, mentre grep potrebbe costruire un elenco completo delle partite. Dico "potrebbe" perché Perl potrebbe idealmente ottimizzare if (grep .... Potrebbe non farlo. Ma List::MoreUtils::any termina presto ed è più descrittivo rispetto all'idioma if (grep ....

2. Fare un hash che ha le chiavi di tutte le stringhe che si desidera abbinare

   my %matcher; 
   
   @matcher{qw{str1 str2 str3}} =(); 
   
   if (exists $matcher{$var}) { 
       ... 
   } 
   

   Questo ha lo svantaggio di un tempo di set-up e il costo della memoria utilizzata per l'hash, ma il vantaggio è che il tempo di corrispondenza è più simile a O (log N). Quindi, se hai un sacco di valori diversi di $var che vuoi testare, potrebbe essere più veloce nel complesso.

3. Fai un espressione regolare che corrisponde a tutte le vostre corde

   if ($var =~ m/^str[123]$/so) { 
       ... 
   } 
   

   OK, quindi questo va bene se le corde sono letteralmente qw{str1 str2 str3}, ma cosa succede se si tratta di una lista di stringhe arbitrarie?

   È possibile utilizzare Regexp::Assemble per fondere insieme un elenco di espressioni regolari in una singola espressione regolare ottimizzata.

Answer 4

Sono semi-scherzando, ma questo lo farà:

use Quantum::Superpositions; 

if ($x == any($a, $b, $c)) { ... } 

Vedi anche questo Perl Monks thread

Answer 5

Per una lista di stringhe fisse, convertire la vostra lista per un hash. Questo è particolarmente utile se stai andando a controllare il tuo elenco più volte, e se la tua lista diventa più grande.

%on_my_list = map {; $_ => 1 } 'str1', 'str2', 'str3', ...; 

if ($on_my_list{$var}) { ... }