Chromium: Come ottenere tutta la forma di una pagina caricata

Question

Cerco di ottenere il nome di tutti i moduli della pagina caricata. Ho fatto questo:

procedure TForm2.Button2Click(Sender: TObject); 
var 
    L: TStringList; 
begin 
    L := TStringList.Create; 

    try 
    Chromium1.Browser.MainFrame.VisitDomProc(
     procedure (const doc: ICefDomDocument) 
     procedure IterateNodes(Node: ICefDomNode); 
     begin 
      if not Assigned(Node) then Exit; 
      repeat 
      if Node.ElementTagName = 'FORM' then 
       L.Add(Node.GetElementAttribute('name')); 

      if Node.HasChildren then IterateNodes(Node.FirstChild); 

      Node := Node.NextSibling; 
      until not Assigned(Node); 
     end; 
     begin 
     IterateNodes(doc.Body); 
     end 
    ); 

    ShowMessage(L.Text); 
    finally 
    FreeAndNil(L); 
    end; 
end; 

Ma non ho alcun risultato. Qualche idea?

Grazie

Answer 1

Con XE2 Update 4

ho capito che il flusso del programma prosegue quando si esegue la procedura parametro in modo che una volta raggiunta la ShowMessage ancora non è stato eseguito questa procedura e quindi la TStringList è vuoto.

Ho messo un controllo di variabile booleano e ha funzionato bene, ma questa non è una soluzione elegante.

Ecco il nuovo codice:

procedure TForm2.Button2Click(Sender: TObject); 
var 
    L: TStringList; 
    Finish: Boolean; 
begin 
    L := TStringList.Create; 
    Finish := False; 

    try 
    Chromium1.Browser.MainFrame.VisitDomProc(
     procedure (const doc: ICefDomDocument) 
     procedure IterateNodes(Node: ICefDomNode); 
     begin 
      if not Assigned(Node) then Exit; 
      repeat 
      if SameText(Node.ElementTagName, 'FORM') then 
      begin 
       L.Add(Node.GetElementAttribute('name')); 
      end; 

      if Node.HasChildren then 
       IterateNodes(Node.FirstChild); 

      Node := Node.NextSibling; 
      until not Assigned(Node); 
     end; 
     begin 
     IterateNodes(doc.Body); 
     Finish := True; 
     end 
    ); 

    repeat Application.ProcessMessages until (Finish); 
    ShowMessage(L.Text); 
    finally 
    FreeAndNil(L); 
    end; 
end; 

Answer 2

sono riuscito a ottenere l'intera pagina come questa:

1. iniettare un elemento DOM - testo.

ChromiumWB.Browser.MainFrame.ExecuteJavaScript('$("body").prepend(''<input type="text" id="msoftval" value=""/>'')', '', 0); 

2. utilizzare jQuery o js per ottenere html corpo in elemento iniettato.

mResult := ''; 
ChromiumWB.Browser.MainFrame.ExecuteJavaScript('$("#msoftval").val($("body").html());', '', 0); 
ChromiumWB.Browser.MainFrame.VisitDomProc(getResult); 
while mResult = '' do Application.ProcessMessages; 
Memo1.Text := mResult; 

3. attendere fino 'VisitDomProc' Fine- rendono sincronizzazione.

procedure TForm44.getResult(const doc: ICefDomDocument); 
var 
    q: ICefDomNode; 
begin 
    q := doc.GetElementById('msoftval'); 
    if Assigned(q) then 
    mResult := q.GetValue 
    else 
    mResult := '-'; 
end;