Come posso controllare l'estensione di un file usando Perl?

Question

Al mio script perl, un file viene passato come argomento. Il file può essere un file .txt o un file .zip contenente il file .txt.

voglio scrivere codice che assomigli a questo

if ($file is a zip) { 

    unzip $file 
    $file =~ s/zip$/txt/; 
} 

Un modo per controllare l'estensione è quello di fare una spaccatura sulla . e quindi abbinare l'ultimo risultato nella matrice (restituito da split).

C'è un modo migliore?

Answer 1

È possibile utilizzare File :: Basename per questo.

#!/usr/bin/perl 

use 5.010; 
use strict; 
use warnings; 

use File::Basename; 

my @exts = qw(.txt .zip); 

while (my $file = <DATA>) { 
    chomp $file; 
    my ($name, $dir, $ext) = fileparse($file, @exts); 

    given ($ext) { 
    when ('.txt') { 
     say "$file is a text file"; 
    } 
    when ('.zip') { 
     say "$file is a zip file"; 
    } 
    default { 
     say "$file is an unknown file type"; 
    } 
    } 
} 

__DATA__ 
file.txt 
file.zip 
file.pl 

L'esecuzione di questo dà:

$ ./files 
file.txt is a text file 
file.zip is a zip file 
file.pl is an unknown file type 

Answer 2

Come controllare la fine del nome file?

if ($file =~ /\.zip$/i) { 

e poi:

use strict; 
use Archive::Extract; 

if ($file =~ /\.zip$/i) { 
    my $ae = Archive::Extract->new(archive => $file); 
    my $ok = $ae->extract(); 
    my $files = $ae->files(); 
} 

ulteriori informazioni here.

Answer 3

È possibile controllare l'estensione del file utilizzando un match regex come:

if($file =~ /\.zip$/i) { 
     # $file is a zip file 
} 

Answer 4

Perché si basano su estensione del file? Basta provare a decomprimere e utilizzare la gestione delle eccezioni appropriata:

eval { 
    # try to unzip the file 
}; 

if ($@) { 
    # not a zip file 
} 

Answer 5

Un'altra soluzione è quella di fare uso di File::Type che determina il tipo di file binario.

use strict; 
use warnings; 

use File::Type; 

my $file  = '/path/to/file.ext'; 
my $ft  = File::Type->new(); 
my $file_type = $ft->mime_type($file); 

if ($file_type eq 'application/octet-stream') { 
    # possibly a text file 
} 
elsif ($file_type eq 'application/zip') { 
    # file is a zip archive 
} 

In questo modo, non è necessario gestire estensioni mancanti/errate.

Answer 6

So che questa domanda è di diversi anni, ma per chiunque che viene qui in futuro, un modo semplice per spezzare un percorso di file nel suo percorso costituente , nomefile, basename e l'estensione è la seguente.

use File::Basename; 

my $filepath = '/foo/bar.txt'; 

my ($basename, $parentdir, $extension) = fileparse($filepath, qr/\.[^.]*$/); 
my $filename = $basename . $extension; 

È possibile verificare i risultati con il seguente.

my @test_paths = (
    '/foo/bar/fish.wibble', 
    '/foo/bar/fish.', 
    '/foo/bar/fish.asdf.d', 
    '/foo/bar/fish.wibble.', 
    '/fish.wibble', 
    'fish.wibble', 
); 

foreach my $this_path (@test_paths) { 
    print "Current path: $this_path\n"; 
    my ($this_basename, $parentdir, $extension) = fileparse($this_path, qr/\.[^.]*$/); 
    my $this_filename = $this_basename . $extension; 

    foreach my $var (qw/$parentdir $this_filename $this_basename $extension/) { 
     print "$var = '" . eval($var) . "'\n"; 
    } 

    print "\n\n"; 
} 

Spero che questo aiuti.