Come assegnare un risultato exec a una variabile sql?

Question

Come si assegna il risultato di una chiamata exec a una variabile in SQL? Ho un proc memorizzato chiamato up_GetBusinessDay, che restituisce una singola data.

può fare qualcosa di simile:

exec @PreviousBusinessDay = dbo.up_GetBusinessDay @Date, -1 

Answer 1

Uso sempre il valore restituito per passare lo stato di errore. Se devi restituire un valore, utilizzerei un parametro di output.

stored procedure di esempio, con un parametro OUTPUT:

CREATE PROCEDURE YourStoredProcedure 
(
    @Param1 int 
    ,@Param2 varchar(5) 
    ,@Param3 datetime OUTPUT 
) 
AS 
IF ISNULL(@Param1,0)>5 
BEGIN 
    SET @Param3=GETDATE() 
END 
ELSE 
BEGIN 
    SET @Param3='1/1/2010' 
END 
RETURN 0 
GO 

chiamata alla stored procedure, con un parametro OUTPUT:

DECLARE @OutputParameter datetime 
     ,@ReturnValue  int 

EXEC @ReturnValue=YourStoredProcedure 1,null, @OutputParameter OUTPUT 
PRINT @ReturnValue 
PRINT CONVERT(char(23),@OutputParameter ,121) 

USCITA:

0 
2010-01-01 00:00:00.000 

Answer 2

Dal documentation (supponendo che si utilizza SQL-Server):

USE AdventureWorks; 
GO 
DECLARE @returnstatus nvarchar(15); 
SET @returnstatus = NULL; 
EXEC @returnstatus = dbo.ufnGetSalesOrderStatusText @Status = 2; 
PRINT @returnstatus; 
GO 

Quindi sì, dovrebbe funzionare in questo modo.

Answer 3

questo funzionerà se desideri semplicemente restituire un numero intero:

DECLARE @ResultForPos INT 
EXEC @ResultForPos = storedprocedureName 'InputParameter' 
SELECT @ResultForPos 

Answer 4

declare @EventId int 

CREATE TABLE #EventId (EventId int) 

insert into #EventId exec rptInputEventId 

set @EventId = (select * from #EventId) 

drop table #EventId